reserve A,x,y,z,u for set,
  m,n for Element of NAT;

theorem
  for F being non empty Poset, A be Subset of F st A is finite & A <> {}
  & for B,C being Element of F st B in A & C in A holds B <= C or C <= B ex m
being Element of F st m in A & for C being Element of F st C in A holds m <= C
proof
  let F be non empty Poset;
  defpred P[set] means $1 <> {} implies ex m being Element of F st m in $1 &
  for C being Element of F st C in $1 holds m <= C;
  let A be Subset of F such that
A1: A is finite and
A2: A <> {} and
A3: for B,C being Element of F st B in A & C in A holds B <= C or C <= B;
A4: now
    let x be Element of F, B be Subset of F such that
A5: x in A and
A6: B c= A and
A7: P[B];
    reconsider x9 = x as Element of F;
    now
      per cases;
      suppose
A8:     not ex y being Element of F st y in B & y <=x9;
        assume B \/ {x} <> {};
        take m = x9;
        x in {x} by TARSKI:def 1;
        hence m in B \/ {x} by XBOOLE_0:def 3;
        let C be Element of F;
        assume C in B \/ {x};
        then
A9:     C in B or C in {x} by XBOOLE_0:def 3;
        then not C <=x9 or C=x by A8,TARSKI:def 1;
        hence m <= C by A3,A5,A6,A9,TARSKI:def 1;
      end;
      suppose
A10:    ex y being Element of F st y in B & y <=x9;
        assume B \/ {x} <> {};
        consider y being Element of F such that
A11:    y in B and
A12:    y <=x9 by A10;
        consider m being Element of F such that
A13:    m in B and
A14:    for C being Element of F st C in B holds m <= C by A7,A11;
        take m;
        thus m in B \/ {x} by A13,XBOOLE_0:def 3;
        let C be Element of F;
        assume C in B \/ {x};
        then
A15:    C in B or C in {x} by XBOOLE_0:def 3;
        m <= y by A11,A14;
        then m <= x9 by A12,ORDERS_2:3;
        hence m <= C by A14,A15,TARSKI:def 1;
      end;
    end;
    hence P[B \/ {x}];
  end;
A16: P[{}(the carrier of F)];
  P[A] from PRE_POLY:sch 2(A1,A16,A4);
  hence thesis by A2;
end;
