 reserve x,y,z for object,
   i,j,k,l,n,m for Nat,
   D,E for non empty set;
 reserve M for Matrix of D;
 reserve L for Matrix of E;

theorem
  for i being Nat st M = L & i in dom M
  holds Line(M,i) = Line(L,i)
  proof
    let i be Nat;
    assume AS1: M = L & i in dom M;
    A1: len (Line(M,i)) = width M
    & for j st j in Seg width M holds (Line(M,i)).j = M*(i,j)
    by MATRIX_0:def 7;
    A2: len (Line(L,i)) = width L
    & for j st j in Seg width L holds (Line(L,i)).j = L*(i,j)
    by MATRIX_0:def 7;
    A3: dom (Line(M,i)) = Seg width M by A1,FINSEQ_1:def 3
    .= dom (Line(L,i)) by AS1,A2, FINSEQ_1:def 3;
    for j st j in dom (Line(M,i)) holds (Line(M,i)).j = (Line(L,i)).j
    proof
      let j;
      assume j in dom (Line(M,i)); then
      A4:j in Seg (width M) by FINSEQ_1:def 3,A1;
      then [i,j] in Indices M by AS1,ZFMISC_1:87; then
      A5: M*(i,j) = L*(i,j) by AS1,EQ2;
      thus (Line(M,i)).j = M*(i,j) by A4,MATRIX_0:def 7
      .= (Line(L,i)).j by AS1,A4,A5,MATRIX_0:def 7;
    end;
    hence thesis by A3;
  end;
