reserve Y for non empty set,
  G for Subset of PARTITIONS(Y),
  A,B,C,D,E,F for a_partition of Y;

theorem
  for G being Subset of PARTITIONS(Y), A,B,C,D,E being a_partition of Y,
z,u being Element of Y st G is independent & G={A,B,C,D,E} & A<>B & A<>C & A<>D
& A<>E & B<>C & B<>D & B<>E & C<>D & C<>E & D<>E & EqClass(z,C '/\' D '/\' E)=
EqClass(u,C '/\' D '/\' E) holds EqClass(u,CompF(A,G)) meets EqClass(z,CompF(B,
  G))
proof
  let G be Subset of PARTITIONS(Y);
  let A,B,C,D,E be a_partition of Y;
  let z,u be Element of Y;
  assume that
A1: G is independent and
A2: G={A,B,C,D,E} and
A3: A<>B and
A4: A<>C & A<>D & A<>E and
A5: B<>C & B<>D & B<>E and
A6: C<>D & C<>E & D<>E and
A7: EqClass(z,C '/\' D '/\' E)=EqClass(u,C '/\' D '/\' E);
  set h = (B .--> EqClass(u,B)) +* (C .--> EqClass(u,C)) +* (D .--> EqClass(u,
  D)) +* (E .--> EqClass(u,E)) +* (A .--> EqClass(z,A));
A8: h.B = EqClass(u,B) by A3,A4,A5,A6,Th26;
A9: h.E = EqClass(u,E) by A3,A4,A5,A6,Th26;
A10: h.D = EqClass(u,D) by A3,A4,A5,A6,Th26;
A11: h.C = EqClass(u,C) by A3,A4,A5,A6,Th26;
A12: rng h = {h.A,h.B,h.C,h.D,h.E} by Th28;
  rng h c= bool Y
  proof
    let t be object;
    assume
A13: t in rng h;
    now
      per cases by A12,A13,ENUMSET1:def 3;
      case
        t=h.A;
        then t=EqClass(z,A) by A3,A4,A5,A6,Th26;
        hence thesis;
      end;
      case
        t=h.B;
        hence thesis by A8;
      end;
      case
        t=h.C;
        hence thesis by A11;
      end;
      case
        t=h.D;
        hence thesis by A10;
      end;
      case
        t=h.E;
        hence thesis by A9;
      end;
    end;
    hence thesis;
  end;
  then reconsider FF=rng h as Subset-Family of Y;
A14: dom h = G by A2,Th27;
  for d being set st d in G holds h.d in d
  proof
    let d be set;
    assume
A15: d in G;
    now
      per cases by A2,A15,ENUMSET1:def 3;
      case
A16:    d=A;
        h.A=EqClass(z,A) by A3,A4,A5,A6,Th26;
        hence thesis by A16;
      end;
      case
A17:    d=B;
        h.B=EqClass(u,B) by A3,A4,A5,A6,Th26;
        hence thesis by A17;
      end;
      case
A18:    d=C;
        h.C=EqClass(u,C) by A3,A4,A5,A6,Th26;
        hence thesis by A18;
      end;
      case
A19:    d=D;
        h.D=EqClass(u,D) by A3,A4,A5,A6,Th26;
        hence thesis by A19;
      end;
      case
A20:    d=E;
        h.E=EqClass(u,E) by A3,A4,A5,A6,Th26;
        hence thesis by A20;
      end;
    end;
    hence thesis;
  end;
  then (Intersect FF)<>{} by A1,A14,BVFUNC_2:def 5;
  then consider m being object such that
A21: m in Intersect FF by XBOOLE_0:def 1;
  A in dom h by A2,A14,ENUMSET1:def 3;
  then
A22: h.A in rng h by FUNCT_1:def 3;
  then
A23: m in meet FF by A21,SETFAM_1:def 9;
  then
A24: m in h.A by A22,SETFAM_1:def 1;
  D in dom h by A2,A14,ENUMSET1:def 3;
  then h.D in rng h by FUNCT_1:def 3;
  then
A25: m in h.D by A23,SETFAM_1:def 1;
  C in dom h by A2,A14,ENUMSET1:def 3;
  then h.C in rng h by FUNCT_1:def 3;
  then
A26: m in h.C by A23,SETFAM_1:def 1;
  B in dom h by A2,A14,ENUMSET1:def 3;
  then h.B in rng h by FUNCT_1:def 3;
  then m in h.B by A23,SETFAM_1:def 1;
  then m in EqClass(u,B) /\ EqClass(u,C) by A8,A11,A26,XBOOLE_0:def 4;
  then
A27: m in EqClass(u,B) /\ EqClass(u,C) /\ EqClass(u,D) by A10,A25,
XBOOLE_0:def 4;
  E in dom h by A2,A14,ENUMSET1:def 3;
  then h.E in rng h by FUNCT_1:def 3;
  then m in h.E by A23,SETFAM_1:def 1;
  then
A28: m in EqClass(u,B) /\ EqClass(u,C) /\ EqClass(u,D) /\ EqClass(u,E) by A9
,A27,XBOOLE_0:def 4;
  set GG=EqClass(u,(((B '/\' C) '/\' D) '/\' E));
  set I=EqClass(z,A);
  GG = EqClass(u,B '/\' C '/\' D) /\ EqClass(u,E) by Th1;
  then
A29: GG = EqClass(u,B '/\' C) /\ EqClass(u,D) /\ EqClass(u,E) by Th1;
  h.A = EqClass(z,A) by A3,A4,A5,A6,Th26;
  then m in EqClass(u,B) /\ EqClass(u,C) /\ EqClass(u,D) /\ EqClass(u,E) /\
  EqClass(z,A) by A24,A28,XBOOLE_0:def 4;
  then GG /\ I <> {} by A29,Th1;
  then consider p being object such that
A30: p in GG /\ I by XBOOLE_0:def 1;
  reconsider p as Element of Y by A30;
  set K=EqClass(p,C '/\' D '/\' E);
A31: p in GG by A30,XBOOLE_0:def 4;
A32: z in I by EQREL_1:def 6;
  set L=EqClass(z,C '/\' D '/\' E);
A33: p in EqClass(p,C '/\' D '/\' E) by EQREL_1:def 6;
  GG = EqClass(u,((B '/\' (C '/\' D)) '/\' E)) by PARTIT1:14;
  then GG = EqClass(u,B '/\' (C '/\' D '/\' E)) by PARTIT1:14;
  then GG c= L by A7,BVFUNC11:3;
  then K meets L by A31,A33,XBOOLE_0:3;
  then K=L by EQREL_1:41;
  then z in K by EQREL_1:def 6;
  then
A34: z in I /\ K by A32,XBOOLE_0:def 4;
  set H=EqClass(z,CompF(B,G));
  A '/\' (C '/\' D '/\' E) = A '/\' (C '/\' D) '/\' E by PARTIT1:14;
  then
A35: A '/\' (C '/\' D '/\' E) = A '/\' C '/\' D '/\' E by PARTIT1:14;
A36: p in K & p in I by A30,EQREL_1:def 6,XBOOLE_0:def 4;
  then p in I /\ K by XBOOLE_0:def 4;
  then I /\ K in INTERSECTION(A,C '/\' D '/\' E) & not I /\ K in {{}} by
SETFAM_1:def 5,TARSKI:def 1;
  then
A37: I /\ K in INTERSECTION(A,C '/\' D '/\' E) \ {{}} by XBOOLE_0:def 5;
  CompF(B,G) = A '/\' C '/\' D '/\' E by A2,A3,A5,Th22;
  then I /\ K in CompF(B,G) by A37,A35,PARTIT1:def 4;
  then
A38: I /\ K = H or I /\ K misses H by EQREL_1:def 4;
  z in H by EQREL_1:def 6;
  then p in H by A36,A34,A38,XBOOLE_0:3,def 4;
  then p in GG /\ H by A31,XBOOLE_0:def 4;
  then GG meets H by XBOOLE_0:4;
  hence thesis by A2,A3,A4,Th21;
end;
