reserve Y for non empty set;
reserve B for Subset of Y;

theorem
  for a being Function of Y,BOOLEAN,PA being a_partition of Y
  holds B_INF(a,PA) is_dependent_of PA
proof
  let a be Function of Y,BOOLEAN;
  let PA be a_partition of Y;
  for F being set st F in PA holds for x1,x2 being set st x1 in F & x2 in
  F holds B_INF(a,PA).x1=B_INF(a,PA).x2
  proof
    let F be set;
    assume
A1: F in PA;
    let x1,x2 be set;
    assume that
A2: x1 in F and
A3: x2 in F;
    reconsider x1 as Element of Y by A1,A2;
A4: EqClass(x1,PA) = F or EqClass(x1,PA) misses F by A1,EQREL_1:def 4;
    reconsider x2 as Element of Y by A1,A3;
A5: x1 in EqClass(x1,PA) & EqClass(x2,PA) = F
           by A1,A3,EQREL_1:def 6;
    per cases;
    suppose
A6:   for x being Element of Y st x in EqClass(x1,PA) holds a.x=TRUE;
      then (B_INF(a,PA)).x1 = TRUE by Def16;
      hence thesis by A2,A4,A5,A6,Def16,XBOOLE_0:3;
    end;
    suppose
A7:   not (for x being Element of Y st x in EqClass(x1,PA) holds a.x= TRUE);
      then (B_INF(a,PA)).x1 = FALSE by Def16;
      hence thesis by A2,A4,A5,A7,Def16,XBOOLE_0:3;
    end;
  end;
  hence thesis;
end;
