reserve x,y,z for object,X,Y for set;
reserve N for e_net;

theorem
  e_entrance(N) * (e_entrance(N) \ id(e_shore N)) = {} &
  e_escape(N) * (e_escape(N) \ id(e_shore N)) = {}
proof
  set P = ((the escape of N) \ id N);
  set Q = ((the entrance of N) \ id(the carrier of N));
  set S = id((the carrier of N) \ rng the entrance of N);
  set T = id((the carrier of N) \ rng the escape of N);
  set R = id the carrier of N;
A1: S c= R by SYSREL:15,XBOOLE_1:36;
  (Q~) * ((Q~) \ R) c= (Q~) * (Q~) by RELAT_1:29,XBOOLE_1:36;
  then (Q~) * ((Q~) \ R) c= {} by Th25;
  then
A2: (Q~) * ((Q~) \ R) = {} by XBOOLE_1:3;
  S * ((Q~) \ R) c= S * (Q~) by RELAT_1:29,XBOOLE_1:36;
  then S * ((Q~) \ R) c= {} by Th28;
  then
A3: S * ((Q~) \ R) = {} by XBOOLE_1:3;
A4: e_escape(N) * (e_escape(N) \ id(e_shore(N))) = ((Q~) \/ S) * (((Q~) \
  R) \/ (S \ R)) by XBOOLE_1:42
    .= ((Q~) \/ S) * (((Q~) \ R) \/ {}) by A1,XBOOLE_1:37
    .= {} \/ {} by A2,A3,SYSREL:6
    .= {};
A5: T c= R by SYSREL:15,XBOOLE_1:36;
  T * ((P~) \ R) c= T * (P~) by RELAT_1:29,XBOOLE_1:36;
  then T * ((P~) \ R) c= {} by Th28;
  then
A6: T * ((P~) \ R) = {} by XBOOLE_1:3;
  (P~) * ((P~) \ R) c= (P~) * (P~) by RELAT_1:29,XBOOLE_1:36;
  then (P~) * ((P~) \ R) c= {} by Th25;
  then
A7: (P~) * ((P~) \ R) = {} by XBOOLE_1:3;
  e_entrance(N) * (e_entrance(N) \ id(e_shore N)) = ((P~) \/ T) * (((P
  ~) \ R) \/ (T \ R)) by XBOOLE_1:42
    .= ((P~) \/ T) * (((P~) \ R) \/ {}) by A5,XBOOLE_1:37
    .= {} \/ {} by A7,A6,SYSREL:6
    .= {};
  hence thesis by A4;
end;
