
theorem TrF2:
{f where f is Function of REAL,REAL :
ex a,b be Real st for th be Real holds f.th= 1/2*cos(a*th+b)+1/2}
 c= Membership_Funcs (REAL)
proof
 let x be object;
 assume x in {f where f is Function of REAL,REAL :
 ex a,b be Real st for th be Real holds f.th= 1/2*cos(a*th+b)+1/2};
 then consider f be Function of REAL,REAL such that
 A1: x=f and
 A2: ex a,b be Real st for th be Real holds f.th= 1/2*cos(a*th+b)+1/2;
 rng f c= [.0,1.]
 proof
  let y be object;
  assume y in rng f;then
  consider th be object such that
  B2: th in REAL and B3: y = f . th by FUNCT_2:11;
  reconsider th as Real by B2;
  consider a,b be Real such that
  B1:for th0 be Real holds f.th0= 1/2*cos(a*th0+b)+1/2 by A2;
  |.cos(a*th+b) .| <= 1 by SIN_COS:27; then
  -1 <= cos(a*th+b) & cos(a*th+b) <= 1 by ABSVALUE:5; then
  1/2*(-1) <= 1/2*cos(a*th+b) & 1/2*cos(a*th+b) <= 1/2*1 by XREAL_1:64;
  then
  B4: -1/2+1/2 <= cos(a*th+b)*1/2+1/2 &
  1/2*cos(a*th+b)+1/2 <= 1/2+1/2 by XREAL_1:7;
  y = 1/2*cos(a*th+b)+1/2 by B1,B3;
  hence thesis by B4;
 end;
 then f is [.0,1.] -valued;
 hence thesis by Def1,A1;
end;
