
theorem Th30:
  for G1, G2 being _Graph
  for f being PartFunc of the_Vertices_of G1, the_Vertices_of G2
  for g being PartFunc of the_Edges_of G1, the_Edges_of G2
  st ((for e being object holds e in dom g implies
      (the_Source_of G1).e in dom f & (the_Target_of G1).e in dom f) &
    for e,v,w being object st e in dom g & v in dom f & w in dom f
    holds e DJoins v,w,G1 implies g.e DJoins f.v,f.w,G2)
  holds [f,g] is directed PGraphMapping of G1, G2
proof
  let G1, G2 be _Graph;
  let f be PartFunc of the_Vertices_of G1, the_Vertices_of G2;
  let g be PartFunc of the_Edges_of G1, the_Edges_of G2;
  assume that
    A1: for e being object holds e in dom g implies
      (the_Source_of G1).e in dom f & (the_Target_of G1).e in dom f and
    A2: for e,v,w being object st e in dom g & v in dom f & w in dom f
      holds e DJoins v,w,G1 implies g.e DJoins f.v,f.w,G2;
  A3: now
    let e,v,w be object;
    assume A4: e in dom g & v in dom f & w in dom f;
    assume e Joins v,w,G1;
    then per cases by GLIB_000:16;
    suppose e DJoins v,w,G1;
      then g.e DJoins f.v,f.w,G2 by A2, A4;
      hence g.e Joins f.v,f.w,G2 by GLIB_000:16;
    end;
    suppose e DJoins w,v,G1;
      then g.e DJoins f.w,f.v,G2 by A2, A4;
      hence g.e Joins f.v,f.w,G2 by GLIB_000:16;
    end;
  end;
  reconsider F = [f,g] as PGraphMapping of G1, G2 by A1, A3, Th8;
  F is directed by A2;
  hence thesis;
end;
