reserve i,j,k,i1,j1 for Nat,
  p for Point of TOP-REAL 2,
  x for set;
reserve f for non constant standard special_circular_sequence;
reserve P for Subset of TOP-REAL 2;

theorem
  LSeg(1/2*((GoB f)*(len GoB f -' 1,width GoB f)+ (GoB f)*(len GoB f,
  width GoB f))+|[0,1]|, (GoB f)*(len GoB f,width GoB f)+|[1,1]|) misses L~f
proof
A1: 1 <= width GoB f by GOBOARD7:33;
  now
A2: 1 < len GoB f by GOBOARD7:32;
    then
A3: len GoB f -' 1 +1 = len GoB f by XREAL_1:235;
    then
A4: len GoB f -' 1 <= len GoB f by NAT_1:11;
A5: (GoB f)*(len GoB f,width GoB f)`2 = (GoB f)*(1,width GoB f)`2 by A1,A2,
GOBOARD5:1;
    then
    ((GoB f)*(len GoB f,width GoB f)+|[1,1]|)`2 = (GoB f)*(1,width GoB f)
    `2+|[1,1]|`2 by TOPREAL3:2
      .= (GoB f)*(1,width GoB f)`2+1 by EUCLID:52;
    then
A6: (GoB f)*(len GoB f,width GoB f)+|[1,1]| = |[((GoB f)*(len GoB f,width
    GoB f)+|[1,1]|)`1, (GoB f)*(1,width GoB f)`2+1]| by EUCLID:53;
    1 <= len GoB f -' 1 by A2,A3,NAT_1:13;
    then
A7: (GoB f)*(len GoB f -' 1,width GoB f)`2 = (GoB f)*(1,width GoB f)`2 by A1,A4
,GOBOARD5:1;
    (1/2*((GoB f)*(len GoB f -' 1,width GoB f) +(GoB f)*(len GoB f,width
GoB f))+|[0,1]|)`2 = (1/2*((GoB f)*(len GoB f -' 1,width GoB f) +(GoB f)*(len
    GoB f,width GoB f)))`2+|[0,1]|`2 by TOPREAL3:2
      .= 1/2*((GoB f)*(len GoB f -' 1,width GoB f) +(GoB f)*(len GoB f,width
    GoB f))`2+|[0,1]|`2 by TOPREAL3:4
      .= 1/2*((GoB f)*(1,width GoB f)`2+(GoB f)*(1,width GoB f)`2)+|[0,1]|`2
    by A7,A5,TOPREAL3:2
      .= 1*((GoB f)*(1,width GoB f))`2+1 by EUCLID:52;
    then
A8: 1/2*((GoB f)*(len GoB f -' 1,width GoB f) +(GoB f)*(len GoB f,width
GoB f))+|[0,1]| = |[(1/2*((GoB f)*(len GoB f -' 1,width GoB f) +(GoB f)*(len
    GoB f,width GoB f))+|[0,1]|)`1, (GoB f)*(1,width GoB f)`2+1]| by EUCLID:53;
    let p;
    assume p in LSeg(1/2*((GoB f)*(len GoB f -' 1,width GoB f)+ (GoB f)*(len
    GoB f,width GoB f))+|[0,1]|, (GoB f)*(len GoB f,width GoB f)+|[1,1]|);
    then p`2 = (GoB f)*(1,width GoB f)`2 + 1 by A8,A6,TOPREAL3:12;
    hence p`2 > (GoB f)*(1,width GoB f)`2 by XREAL_1:29;
  end;
  hence thesis by Th24;
end;
