reserve x for Real;
reserve p,q for Point of TOP-REAL 2;

theorem Th30:
  for p being Point of TOP-REAL 2 st p<>0.TOP-REAL 2 holds ((p`1<=
p`2 & -p`2<=p`1 or p`1>=p`2 & p`1<=-p`2) implies (Sq_Circ").p=|[p`1*sqrt(1+(p`1
/p`2)^2),p`2*sqrt(1+(p`1/p`2)^2)]|) & (not(p`1<=p`2 & -p`2<=p`1 or p`1>=p`2 & p
`1<=-p`2) implies (Sq_Circ").p=|[p`1*sqrt(1+(p`2/p`1)^2),p`2*sqrt(1+(p`2/p`1)^2
  )]|)
proof
  let p be Point of TOP-REAL 2;
A1: -p`2<p`1 implies --p`2>-p`1 by XREAL_1:24;
  assume
A2: p<>0.TOP-REAL 2;
  hereby
    assume
A3: p`1<=p`2 & -p`2<=p`1 or p`1>=p`2 & p`1<=-p`2;
    now
      per cases by A3;
      case
A4:     p`1<=p`2 & -p`2<=p`1;
        now
          assume
A5:       p`2<=p`1 & -p`1<=p`2 or p`2>=p`1 & p`2<=-p`1;
A6:       now
            per cases by A5;
            case
              p`2<=p`1 & -p`1<=p`2;
              hence p`1=p`2 or p`1=-p`2 by A4,XXREAL_0:1;
            end;
            case
              p`2>=p`1 & p`2<=-p`1;
              then -p`2>=--p`1 by XREAL_1:24;
              hence p`1=p`2 or p`1=-p`2 by A4,XXREAL_0:1;
            end;
          end;
          now
            per cases by A6;
            case
              p`1=p`2;
              hence
              (Sq_Circ").p =|[p`1*sqrt(1+(p`1/p`2)^2),p`2*sqrt(1+(p`1/p`2
              )^2)]| by A2,A5,Th28;
            end;
            case
              p`1=-p`2;
              then p`1<>0 & -p`1=p`2 by A2,EUCLID:53,54;
              then p`1/p`2=-1 & p`2/p`1=-1 by XCMPLX_1:197,198;
              hence
              (Sq_Circ").p=|[p`1*sqrt(1+(p`1/p`2)^2),p`2*sqrt(1+(p`1/p`2)
              ^2) ]| by A2,A5,Th28;
            end;
          end;
          hence (Sq_Circ").p=|[p`1*sqrt(1+(p`1/p`2)^2),p`2*sqrt(1+(p`1/p`2)^2)
          ]|;
        end;
        hence (Sq_Circ").p=|[p`1*sqrt(1+(p`1/p`2)^2),p`2*sqrt(1+(p`1/p`2)^2)]|
        by Th28;
      end;
      case
A7:     p`1>=p`2 & p`1<=-p`2;
        now
          assume
A8:       p`2<=p`1 & -p`1<=p`2 or p`2>=p`1 & p`2<=-p`1;
A9:       now
            per cases by A8;
            case
              p`2<=p`1 & -p`1<=p`2;
              then --p`1>=-p`2 by XREAL_1:24;
              hence p`1=p`2 or p`1=-p`2 by A7,XXREAL_0:1;
            end;
            case
              p`2>=p`1 & p`2<=-p`1;
              hence p`1=p`2 or p`1=-p`2 by A7,XXREAL_0:1;
            end;
          end;
          now
            per cases by A9;
            case
              p`1=p`2;
              hence
              (Sq_Circ").p=|[p`1*sqrt(1+(p`1/p`2)^2),p`2*sqrt(1+(p`1/p`2)
              ^2) ]| by A2,A8,Th28;
            end;
            case
A10:          p`1=-p`2;
              then p`1<>0 & -p`1=p`2 by A2,EUCLID:53,54;
              then
A11:          p`2/p`1=-1 by XCMPLX_1:197;
              p`2<>0 by A2,A10,EUCLID:53,54;
              then p`1/p`2=-1 by A10,XCMPLX_1:197;
              hence
              (Sq_Circ").p=|[p`1*sqrt(1+(p`1/p`2)^2),p`2*sqrt(1+(p`1/p`2)
              ^2) ]| by A2,A8,A11,Th28;
            end;
          end;
          hence (Sq_Circ").p=|[p`1*sqrt(1+(p`1/p`2)^2),p`2*sqrt(1+(p`1/p`2)^2)
          ]|;
        end;
        hence (Sq_Circ").p=|[p`1*sqrt(1+(p`1/p`2)^2),p`2*sqrt(1+(p`1/p`2)^2)]|
        by Th28;
      end;
    end;
    hence (Sq_Circ").p=|[p`1*sqrt(1+(p`1/p`2)^2),p`2*sqrt(1+(p`1/p`2)^2)]|;
  end;
A12: -p`2>p`1 implies --p`2<-p`1 by XREAL_1:24;
  assume not(p`1<=p`2 & -p`2<=p`1 or p`1>=p`2 & p`1<=-p`2);
  hence thesis by A2,A1,A12,Th28;
end;
