reserve a for Real;
reserve p,q for Point of TOP-REAL 2;

theorem Th30:
  for sn being Real, B0 being Subset of TOP-REAL 2, K0 being
Subset of (TOP-REAL 2)|B0, f being Function of ((TOP-REAL 2)|B0)|K0,((TOP-REAL
2)|B0) st -1<sn & sn<1 & f=(sn-FanMorphW)|K0 & B0=NonZero TOP-REAL 2 & K0={p: p
  `1<=0 & p<>0.TOP-REAL 2} holds f is continuous
proof
  defpred P[Point of TOP-REAL 2] means $1`1<=0 & $1<>0.TOP-REAL 2;
  let sn be Real,B0 be Subset of TOP-REAL 2,
      K0 be Subset of (TOP-REAL 2)|B0,f
  be Function of ((TOP-REAL 2)|B0)|K0,((TOP-REAL 2)|B0);
  reconsider K1={p: P[p] } as Subset of TOP-REAL 2 from JGRAPH_2:sch 1;
  assume
A1: -1<sn & sn<1 & f=(sn-FanMorphW)|K0 & B0=NonZero TOP-REAL 2 & K0={p:
  p`1<=0 & p<>0.TOP-REAL 2 };
  K0 c= B0
  proof
    let x be object;
    assume x in K0;
    then
A2: ex p8 being Point of TOP-REAL 2 st x=p8 & p8`1<=0 & p8 <>0.TOP-REAL 2
    by A1;
    then not x in {0.TOP-REAL 2} by TARSKI:def 1;
    hence thesis by A1,A2,XBOOLE_0:def 5;
  end;
  then ((TOP-REAL 2)|B0)|K0=(TOP-REAL 2)|K1 by A1,PRE_TOPC:7;
  hence thesis by A1,Th27;
end;
