reserve i,j,k,n for Nat,
  D for non empty set,
  f, g for FinSequence of D;
reserve G for Go-board,
  f, g for FinSequence of TOP-REAL 2,
  p for Point of TOP-REAL 2,
  r, s for Real,
  x for set;
reserve C for compact non vertical non horizontal non empty Subset of TOP-REAL
  2,
  l, m, i1, i2, j1, j2 for Nat;

theorem Th30:
 for n being Nat for f being standard non constant
special_circular_sequence st f is_sequence_on Gauge(C,n) &
(for k being Nat st 1 <= k & k
+1 <= len f holds left_cell(f,k,Gauge(C,n)) misses C & right_cell(f,k,Gauge(C,n
  )) meets C) &
 (ex i being Nat st 1 <= i & i+1 <= len Gauge(C,n) & f/.1 = Gauge(C,n)*(i,
width Gauge(C,n)) & f/.2 = Gauge(C,n)*(i+1,width Gauge(C,n)) & N-min C in cell(
Gauge(C,n),i,width Gauge(C,n)-'1) & N-min C <> Gauge(C,n)*(i,width Gauge(C,n)-'
  1)) holds N-min L~f = f/.1
proof
  let n be Nat;
  set G = Gauge(C,n);
  let f be standard non constant special_circular_sequence such that
A1: f is_sequence_on G and
A2: for k being Nat st 1 <= k & k+1 <= len f holds left_cell(f,k,G)
    misses C & right_cell(f,k,G) meets C;
  N-min L~f in rng f by SPRECT_2:39;
  then consider m being Nat such that
A3: m in dom f and
A4: f.m = N-min L~f by FINSEQ_2:10;
  reconsider m as Nat;
  consider i,j being Nat such that
A5: [i,j] in Indices G and
A6: f/.m = G*(i,j) by A1,A3,GOBOARD1:def 9;
A7: f/.m = f.m by A3,PARTFUN1:def 6;
A8: (N-min L~f)`2 = N-bound L~f by EUCLID:52;
  set W = W-bound C, S = S-bound C, E = E-bound C, N = N-bound C;
  given i9 being Nat such that
A9: 1 <= i9 and
A10: i9+1 <= len G and
A11: f/.1 = G*(i9,width G) and
A12: f/.2 = G*(i9+1,width G) and
A13: N-min C in cell(G,i9,width G-'1) and
A14: N-min C <> G*(i9,width G-'1);
A15: G*(i9,len G-'1) = |[G*(i9,len G-'1)`1,G*(i9,len G-'1)`2]| & (N-min C)`2
  = N by EUCLID:52,53;
  G*(i,j) = |[W+((E-W)/(2|^n))*(i-2), S+((N-S)/(2|^n))*(j-2)]| by A5,
JORDAN8:def 1;
  then
A16: S+((N-S)/(2|^n))*(j-2) = N-bound L~f by A4,A7,A8,A6,EUCLID:52;
  N > S by JORDAN8:9;
  then 2|^n > 0 & N-S > 0 by NEWTON:83,XREAL_1:50;
  then
A17: (N-S)/(2|^n) > 0 by XREAL_1:139;
A18: (NW-corner L~f)`1 = W-bound L~f & (NE-corner L~f)`1 = E-bound L~f by
EUCLID:52;
A19: 1 <= i by A5,MATRIX_0:32;
A20: (NW-corner L~f)`2 = N-bound L~f & (NE-corner L~f)`2 = N-bound L~f by
EUCLID:52;
A21: m <= len f by A3,FINSEQ_3:25;
A22: 1 <= j by A5,MATRIX_0:32;
  len G = 2|^n+3 by JORDAN8:def 1;
  then
A23: len G >= 3 by NAT_1:12;
  then
A24: 1 < len G by XXREAL_0:2;
  then
A25: 1 <= len G-'1 by NAT_D:49;
  then
A26: len G-'1 < len G by NAT_D:51;
A27: i <= len G by A5,MATRIX_0:32;
A28: j <= width G by A5,MATRIX_0:32;
  then
A29: G*(i,j)`2 = G* (1,j)`2 by A19,A27,A22,GOBOARD5:1;
A30: len f > 4 by GOBOARD7:34;
  1 in dom f by FINSEQ_5:6;
  then
A31: f/.1 in L~f by A30,GOBOARD1:1,XXREAL_0:2;
  then
A32: N-bound L~f >= (f/.1)`2 by PSCOMP_1:24;
A33: len G = width G by JORDAN8:def 1;
A34: i9 < len G by A10,NAT_1:13;
  then G*(i9,j)`2 = G*(1,j)`2 by A9,A22,A28,GOBOARD5:1;
  then G*(i,j)`2 <= G*(i9,len G)`2 by A9,A34,A33,A22,A28,A29,SPRECT_3:12;
  then
A35: N-bound L~f = (f/.1)`2 by A11,A33,A4,A7,A8,A6,A32,XXREAL_0:1;
  [i9,len G] in Indices G by A9,A34,A33,A24,MATRIX_0:30;
  then G*(i9,len G)=|[W+((E-W)/(2|^n))*(i9-2),S+((N-S)/(2|^n))*(len G-2)]| by
JORDAN8:def 1;
  then S+((N-S)/(2|^n))*(len G-2) = N-bound L~f by A11,A33,A35,EUCLID:52;
  then
A36: len G-2 = j-2 by A17,A16,XCMPLX_1:5;
  then
A37: G*(i9,len G)`1 = G*(i9,1)`1 by A9,A34,A33,A22,GOBOARD5:2;
  W-bound L~f <= (f/.1)`1 & (f/.1)`1 <= E-bound L~f by A31,PSCOMP_1:24;
  then f/.1 in LSeg(NW-corner L~f, NE-corner L~f) by A35,A18,A20,GOBOARD7:8;
  then f/.1 in LSeg(NW-corner L~f, NE-corner L~f) /\ L~f by A31,XBOOLE_0:def 4;
  then
A38: (N-min L~f)`1 <= (f/.1)`1 by PSCOMP_1:39;
  then
A39: i <= i9 by A9,A11,A33,A4,A7,A6,A27,A22,A36,GOBOARD5:3;
  then
A40: i < len G by A34,XXREAL_0:2;
  then
A41: i+1 <= len G by NAT_1:13;
A42: len G-'1+1 = len G by A23,XREAL_1:235,XXREAL_0:2;
  then
  N-min C in { |[r9,s9]| where r9,s9 is Real:
   G*(i9,1)`1 <= r9 & r9 <= G*
(i9+1,1)`1 & G*(1,len G-'1)`2 <= s9 & s9 <= G*(1,len G)`2 } by A9,A13,A34,A33
,A25,A26,GOBRD11:32;
  then
  ex r9,s9 being Real
   st N-min C = |[r9,s9]| & G*(i9,1)`1 <= r9 & r9 <= G*
  (i9+1,1)`1 & G*(1,len G-'1)`2 <= s9 & s9 <= G*(1,len G)`2;
  then
A43: (f/.1)`1 <= (N-min C)`1 by A11,A33,A37,EUCLID:52;
  then
A44: (N-min L~f)`1 <= (N-min C)`1 by A38,XXREAL_0:2;
A45: 1 <= m by A3,FINSEQ_3:25;
A46: G*(i9,len G-'1)`2 = N by A9,A34,JORDAN8:14;
A47: N-min C = |[(N-min C)`1,(N-min C)`2]| by EUCLID:53;
A48: (NW-corner C)`2 = N & (NE-corner C)`2 = N by EUCLID:52;
A49: (NW-corner C)`1 = W & (NE-corner C)`1 = E by EUCLID:52;
A50: len G = width G by JORDAN8:def 1;
  G*(i9,len G-'1)`1 = G*(i9,1)`1 by A9,A34,A33,A25,A26,GOBOARD5:2;
  then
A51: G*(i9,len G-'1)`1 < (N-min C)`1 by A11,A14,A33,A37,A43,A47,A15,A46,
XXREAL_0:1;
A52: G*(i,len G)`1 = G*(i,1)`1 by A19,A27,A22,A28,A36,GOBOARD5:2;
  per cases by A21,XXREAL_0:1;
  suppose
    m = len f;
    hence thesis by A4,A7,FINSEQ_6:def 1;
  end;
  suppose
    m < len f;
    then
A53: m+1 <= len f by NAT_1:13;
    then consider i1,j1,i2,j2 being Nat such that
A54: [i1,j1] in Indices G & f/.m = G*(i1,j1) and
A55: [i2,j2] in Indices G and
A56: f/.(m+1) = G*(i2,j2) and
A57: i1 = i2 & j1+1 = j2 or i1+1 = i2 & j1 = j2 or i1 = i2+1 & j1 = j2
    or i1 = i2 & j1 = j2+1 by A1,A45,JORDAN8:3;
A58: right_cell(f,m,G) meets C by A2,A45,A53;
    then consider p being object such that
A59: p in right_cell(f,m,G) and
A60: p in C by XBOOLE_0:3;
    reconsider p as Point of TOP-REAL 2 by A59;
A61: W <= p`1 & p`1 <= E by A60,PSCOMP_1:24;
A62: (N-min C)`2 = N by EUCLID:52;
    then
A63: p`2 <= (N-min C)`2 by A60,PSCOMP_1:24;
A64: G*(1,len G-'1)`2 < G*(1,len G)`2 by A50,A24,A25,A26,GOBOARD5:4;
A65: G*(1,len G-'1)`2 = N by A24,JORDAN8:14;
A66: j2 <= len G by A50,A55,MATRIX_0:32;
    now
      per cases by A5,A6,A36,A54,A57,GOBOARD1:5;
      suppose
        i = i2 & len G+1 = j2;
        hence thesis by A66,NAT_1:13;
      end;
      suppose
A67:    i+1 = i2 & len G = j2;
A68:    cell(G,i,len G-'1) = {|[r,s]| : G*(i,1)`1 <= r & r <= G*(i+1,1)`1
& G*(1,len G-'1)`2 <= s & s <= G*(1,len G-'1+1)`2 } by A50,A19,A25,A26,A40,
GOBRD11:32;
        right_cell(f,m,G) = cell(G,i,len G-'1) by A1,A45,A5,A6,A36,A53,A55,A56
,A67,GOBRD13:24;
        then consider r,s such that
A69:    p = |[r,s]| and
        G*(i,1)`1 <= r and
A70:    r <= G*(i+1,1)`1 and
A71:    G*(1,len G-'1)`2 <= s and
        s <= G*(1,len G-'1+1)`2 by A59,A68;
        p`2 = s by A69,EUCLID:52;
        then p`2 = N by A62,A63,A65,A71,XXREAL_0:1;
        then p in LSeg(NW-corner C, NE-corner C) by A49,A48,A61,GOBOARD7:8;
        then p in LSeg(NW-corner C, NE-corner C) /\ C by A60,XBOOLE_0:def 4;
        then
A72:    (N-min C)`1 <= p`1 by PSCOMP_1:39;
        p`1 = r by A69,EUCLID:52;
        then (N-min C)`1 <= G*(i+1,1)`1 by A70,A72,XXREAL_0:2;
        then
A73:    N-min C in cell(G,i,width G-'1) by A33,A4,A7,A6,A36,A52,A42,A44,A47,A62
,A65,A64,A68;
        N-min C <> G*(i,len G-'1) by A34,A33,A19,A25,A26,A51,A39,SPRECT_3:13;
        hence thesis by A9,A10,A11,A13,A14,A33,A4,A7,A6,A19,A36,A41,A73,Th29;
      end;
      suppose
        i = i2+1 & len G = j2;
        then right_cell(f,m,G) = cell(G,i2,len G) & i2 < len G by A1,A45,A5,A6
,A27,A36,A53,A55,A56,GOBRD13:26,NAT_1:13;
        hence thesis by A2,A45,A53,JORDAN8:15;
      end;
      suppose
A74:    i = i2 & len G = j2+1;
        then
A75:    j2 = len G-'1 by NAT_D:34;
        then
A76:    right_cell(f,m,G) = cell(G,i-'1,len G-'1) by A1,A45,A5,A6,A36,A53,A55
,A56,A74,GOBRD13:28;
        m-'1 <= m by NAT_D:35;
        then
A77:    m-'1 <= len f by A21,XXREAL_0:2;
        now
          1 <= i9+1 by A9,NAT_1:13;
          then
A78:      G*(i9+1,len G)`2 = G* (1,len G)`2 by A10,A33,A24,GOBOARD5:1;
          assume
A79:      m = 1;
          G*(i9,len G)`2 = G*(1,len G)`2 by A9,A34,A33,A24,GOBOARD5:1;
          hence contradiction by A11,A12,A33,A6,A19,A27,A36,A25,A26,A56,A74,A75
,A79,A78,GOBOARD5:4;
        end;
        then m > 1 by A45,XXREAL_0:1;
        then
A80:    m-'1 >= 1 by NAT_D:49;
A81:    m-'1+1 = m by A45,XREAL_1:235;
        then consider i19,j19,i29,j29 being Nat such that
A82:    [i19,j19] in Indices G and
A83:    f/.(m-'1) = G*(i19,j19) and
A84:    [i29,j29] in Indices G & f/.m = G*(i29,j29) &( i19 = i29 &
j19+1 = j29 or i19+1 = i29 & j19 = j29 or i19 = i29+1 & j19 = j29 or i19 = i29
        & j19 = j29+1) by A1,A21,A80,JORDAN8:3;
A85:    1 <= i19 by A82,MATRIX_0:32;
A86:    i19 <= len G by A82,MATRIX_0:32;
        now
          per cases by A5,A6,A36,A84,GOBOARD1:5;
          suppose
A87:        i19 = i & j19+1 = len G;
            then j19 = len G-'1 by NAT_D:34;
            then left_cell(f,m-'1,G) = cell(G,i-'1,len G-'1) by A1,A21,A5,A6
,A36,A80,A81,A82,A83,A87,GOBRD13:21;
            hence contradiction by A2,A21,A58,A76,A80,A81;
          end;
          suppose
A88:        i19+1 = i & j19 = len G;
A89:        G*(i19,j)`2 = G*(1,j)`2 & G*(i,j)`2 = G*(1,j)`2 by A19,A27,A22,A28
,A85,A86,GOBOARD5:1;
            m-'1 in dom f by A80,A77,FINSEQ_3:25;
            then
A90:        f/.(m-'1) in L~f by A30,GOBOARD1:1,XXREAL_0:2;
            then W-bound L~f <= (f/.(m-'1))`1 & (f/.(m-'1))`1 <= E-bound L~f
            by PSCOMP_1:24;
            then f/.(m-'1) in LSeg(NW-corner L~f, NE-corner L~f) by A4,A7,A8,A6
,A36,A18,A20,A83,A88,A89,GOBOARD7:8;
            then
A91:        f/.(m-'1) in LSeg(NW-corner L~f, NE-corner L~f) /\ L~f by A90,
XBOOLE_0:def 4;
            i19 < i by A88,NAT_1:13;
            then (f/.(m-'1))`1 < (f/.m)`1 by A6,A27,A22,A28,A36,A83,A85,A88,
GOBOARD5:3;
            hence contradiction by A4,A7,A91,PSCOMP_1:39;
          end;
          suppose
            i19 = i+1 & j19 = len G;
            then right_cell(f,m-'1,G) = cell(G,i,len G) by A1,A21,A5,A6,A36,A80
,A81,A82,A83,GOBRD13:26;
            hence contradiction by A2,A21,A27,A80,A81,JORDAN8:15;
          end;
          suppose
            i19 = i & j19 = len G+1;
            then len G+1 <= len G+0 by A50,A82,MATRIX_0:32;
            hence contradiction by XREAL_1:6;
          end;
        end;
        hence thesis;
      end;
    end;
    hence thesis;
  end;
end;
