
theorem Th30:
for I,J,K be non empty closed_interval Subset of REAL, x,y be Element of REAL,
 f be PartFunc of [:[:RNS_Real,RNS_Real:],RNS_Real:],RNS_Real,
 g be PartFunc of [:[:REAL,REAL:],REAL:],REAL
 st [:[:I,J:],K:] = dom f & f is_continuous_on [:[:I,J:],K:] & f = g
 holds for e be Real st 0 < e holds
     ex r be Real st 0 < r
      & for u1,u2 be Element of [:REAL,REAL:], x1,y1,x2,y2 be Real
         st u1=[x1,y1] & u2=[x2,y2] & |.x2-x1.| < r & |.y2-y1.| < r
          & u1 in [:I,J:] & u2 in [:I,J:] holds
             for z be Element of REAL st z in K holds
         |. ProjPMap1(|.R_EAL g.|,u2).z - ProjPMap1(|.R_EAL g.|,u1).z .| < e
proof
    let I,J,K be non empty closed_interval Subset of REAL,
    x,y be Element of REAL,
    f be PartFunc of [:[:RNS_Real,RNS_Real:],RNS_Real:],RNS_Real,
    g be PartFunc of [:[:REAL,REAL:],REAL:],REAL;
    assume that
A1: [:[:I,J:],K:] = dom f and
A2: f is_continuous_on [:[:I,J:],K:] and
A3: f = g;

    dom(R_EAL g) = [:[:I,J:],K:] by A1,A3,MESFUNC5:def 7; then
A4: dom |. R_EAL g .| = [:[:I,J:],K:] by MESFUNC1:def 10;

A5:for x be Element of [:REAL,REAL:], y be Element of REAL
     st x in [:I,J:] & y in K holds
      (ProjPMap1(|.R_EAL g.|,x)).y =(|.R_EAL g.|).(x,y)
    & (|.R_EAL g.|).(x,y) = (|.g.|).([x,y])
    proof
     let x be Element of [:REAL,REAL:], y be Element of REAL;
     assume
A6:  x in [:I,J:] & y in K;
     hence (ProjPMap1(|.R_EAL g.|,x)).y =(|.R_EAL g.|).(x,y)
       by A4,ZFMISC_1:87,MESFUN12:def 3;

     [x,y] in dom g by A6,A1,A3,ZFMISC_1:87; then
A7:  [x,y] in dom |.g.| by VALUED_1:def 11;

A8:  (R_EAL g).([x,y]) = g.([x,y]) by MESFUNC5:def 7;
     (|.R_EAL g.|).(x,y) = |.(R_EAL g).([x,y]).|
       by A4,A6,ZFMISC_1:87,MESFUNC1:def 10; then
     (|.R_EAL g.|).(x,y) = |. g.([x,y]) .| by A8,EXTREAL1:12;
     hence (|.R_EAL g.|).(x,y) = (|.g.|).([x,y]) by VALUED_1:def 11,A7;
    end;

    let e be Real;
    assume 0 < e; then
    consider r be Real such that
A9: 0 < r
  & for x1,x2,y1,y2,z1,z2 be Real st x1 in I & x2 in I & y1 in J & y2 in J
     & z1 in K & z2 in K & |.x2-x1.| < r & |.y2-y1.| < r & |.z2-z1.| < r
       holds |. (|.g.|).([x2,y2,z2])-(|.g.|).([x1,y1,z1]) .| < e
         by A2,A3,Th10;
    take r;
    thus 0 < r by A9;

    let u1,u2 be Element of [:REAL,REAL:], x1,y1,x2,y2 be Real;
    assume
A10:u1=[x1,y1] & u2=[x2,y2] & |.x2-x1.| < r & |.y2-y1.| < r
  & u1 in [:I,J:] & u2 in [:I,J:];

    let z be Element of REAL;
A11:x1 in I & x2 in I & y1 in J & y2 in J by A10,ZFMISC_1:87;
    assume
A12:z in K;

    |. z-z .| < r by A9; then
    |. (|.g.|).([x2,y2,z])-(|.g.|).([x1,y1,z]) .| < e by A9,A10,A11,A12; then
A13: |. (|.g.|).([u2,z])-(|.g.|).([ u1,z]).| < e by A10;
a13: (|.g.|).([u2,z])-(|.g.|).([ u1,z]) =
     (|.g.|).([u2,z]) qua ExtReal -(|.g.|).([ u1,z]);

    ProjPMap1(|.R_EAL g.|,u1).z = (|.R_EAL g.|).(u1,z)
  & (|.R_EAL g.|).(u1,z) = (|.g.|).([u1,z])
  & ProjPMap1(|.R_EAL g.|,u2).z = (|.R_EAL g.|).(u2,z)
  & (|.R_EAL g.|).(u2,z) = (|.g.|).([u2,z]) by A5,A10,A12;
    hence thesis by A13,a13,EXTREAL1:12;
end;
