reserve n,i,j,k,l for Nat;
reserve D for non empty set;
reserve c,d for Element of D;
reserve p,q,q9,r for FinSequence of D;
reserve RAS for MidSp-like non empty ReperAlgebraStr over n+2;
reserve a,b,d,pii,p9i for Point of RAS;
reserve p,q for Tuple of (n+1),RAS;
reserve m for Nat of n;
reserve W for ATLAS of RAS;
reserve v for Vector of W;
reserve x,y for Tuple of (n+1),W;
reserve RAS for ReperAlgebra of n;
reserve a,b,pm,p9m,p99m for Point of RAS;
reserve p for Tuple of (n+1),RAS;
reserve W for ATLAS of RAS;
reserve v for Vector of W;
reserve x for Tuple of (n+1),W;

theorem
  RAS has_property_of_zero_in m implies (RAS is_additive_in m iff for x,
  v holds Phi((x+*(m,(x.m)+v))) = Phi(x) + Phi ((x+*(m,v))))
proof
  assume
A1: RAS has_property_of_zero_in m;
  thus RAS is_additive_in m implies for x,v holds Phi((x+*(m,(x.m)+v))) = Phi(
  x) + Phi((x+*(m,v)))
  proof
    set a = the Point of RAS;
    assume
A2: RAS is_additive_in m;
    let x,v;
    set p = (a,x).W, p9m = (a,v).W;
    consider p99m such that
A3: (p99m)@a = (p.m)@(p9m) by MIDSP_1:def 3;
A4: W.(a,p) = x & W.(a,p9m) = v by Th15,MIDSP_2:33;
A5: W.(a,p99m) = W.(a,p.m) + W.(a,p9m) by A3,MIDSP_2:30
      .= x.m + v by A4,Def9;
    (p+*(m,p99m)) = (a,(x+*(m,(x.m)+v))).W
    proof
      set pp = (p+*(m,p99m)), xx = (x+*(m,(x.m)+v));
      set qq = (a,xx).W;
      for i being Nat of n holds pp.i = qq.i
      proof
        let i be Nat of n;
        per cases;
        suppose
A6:       i = m;
          hence pp.i = p99m by Th10
            .= (a,(x.m)+v).W by A5,MIDSP_2:33
            .= (a,xx.m).W by Th13
            .= qq.i by A6,Def8;
        end;
        suppose
A7:       i <> m;
          hence pp.i = p.i by FUNCT_7:32
            .= (a,x.i).W by Def8
            .= (a,xx.i).W by A7,FUNCT_7:32
            .= qq.i by Def8;
        end;
      end;
      hence thesis by Th9;
    end;
    then
A8: Phi((x+*(m,(x.m)+v))) = W.(a,*'(a,(p+*(m,p99m)))) by Lm5;
A9: (p+*(m,p9m)) = (a,(x+*(m,v))).W
    proof
      set pp = (p+*(m,p9m)), qq = (a,(x+*(m,v))).W;
      for i being Nat of n holds pp.i = qq.i
      proof
        let i be Nat of n;
        per cases;
        suppose
A10:      i = m;
          hence pp.i = p9m by Th10
            .= (a,(x+*(m,v)).m).W by Th13
            .= qq.i by A10,Def8;
        end;
        suppose
A11:      i <> m;
          hence pp.i = p.i by FUNCT_7:32
            .= (a,x.i).W by Def8
            .= (a,(x+*(m,v)).i).W by A11,FUNCT_7:32
            .= qq.i by Def8;
        end;
      end;
      hence thesis by Th9;
    end;
    RAS is_semi_additive_in m & *'(a,(p+*(m,(p.m)@p9m))) = *'(a,p)@*'(a,(p
    +*(m, p9m))) by A1,A2,Th29;
    then
A12: W.(a,*'(a,(p+*(m,p99m)))) = W.(a,*'(a,p)) + W.(a,*'(a,(p+*(m,p9m)) ))
    by A3,Lm6;
    Phi(x) = W.(a,*'(a,p)) by Lm5;
    hence thesis by A12,A8,A9,Lm5;
  end;
  thus (for x,v holds Phi((x+*(m,(x.m)+v))) = Phi(x) + Phi((x+*(m,v))))
  implies RAS is_additive_in m
  proof
    assume
A13: for x,v holds Phi((x+*(m,(x.m)+v))) = Phi(x) + Phi ((x+*(m,v)));
    then
A14: RAS is_semi_additive_in m by Lm7;
    for a,pm,p9m,p st p.m = pm holds *'(a,(p+*(m,pm@p9m))) = *'(a,p)@*'(a
    ,(p+*(m,p9m)))
    proof
      let a,pm,p9m,p such that
A15:  p.m = pm;
      set x = W.(a,p), v = W.(a,p9m);
      consider p99m such that
A16:  (p99m)@a = (p.m)@(p9m) by MIDSP_1:def 3;
A17:  (a,x).W = p by Th15;
A18:  W.(a,p99m) = W.(a,p.m) + W.(a,p9m) by A16,MIDSP_2:30
        .= x.m + v by Def9;
      (p+*(m,p99m)) = (a,(x+*(m,(x.m)+v))).W
      proof
        set pp = (p+*(m,p99m)), xx = (x+*(m,(x.m)+v));
        set qq = (a,xx).W;
        for i being Nat of n holds pp.i = qq.i
        proof
          let i be Nat of n;
          per cases;
          suppose
A19:        i = m;
            hence pp.i = p99m by Th10
              .= (a,(x.m)+v).W by A18,MIDSP_2:33
              .= (a,xx.m).W by Th13
              .= qq.i by A19,Def8;
          end;
          suppose
A20:        i <> m;
            hence pp.i = p.i by FUNCT_7:32
              .= (a,x.i).W by A17,Def8
              .= (a,xx.i).W by A20,FUNCT_7:32
              .= qq.i by Def8;
          end;
        end;
        hence thesis by Th9;
      end;
      then
A21:  Phi((x+*(m,(x.m)+v))) = W.(a,*'(a,(p+*(m,p99m)))) by Lm5;
A22:  (a,v).W = p9m by MIDSP_2:33;
      (p+*(m,p9m)) = (a,(x+*(m,v))).W
      proof
        set pp = (p+*(m,p9m)), qq = (a,(x+*(m,v))).W;
        for i being Nat of n holds pp.i = qq.i
        proof
          let i be Nat of n;
          per cases;
          suppose
A23:        i = m;
            hence pp.i = p9m by Th10
              .= (a,(x+*(m,v)).m).W by A22,Th13
              .= qq.i by A23,Def8;
          end;
          suppose
A24:        i <> m;
            hence pp.i = p.i by FUNCT_7:32
              .= (a,x.i).W by A17,Def8
              .= (a,(x+*(m,v)).i).W by A24,FUNCT_7:32
              .= qq.i by Def8;
          end;
        end;
        hence thesis by Th9;
      end;
      then
A25:  Phi((x+*(m,v))) = W.(a,*'(a,(p+*(m,p9m)))) by Lm5;
      Phi(x) = W.(a,*'(a,p)) by Lm4;
      then
      W.(a,*'(a,(p+*(m,p99m)))) = W.(a,*'(a,p)) + W.(a,*' (a,(p+*(m,p9m))
      )) by A13,A21,A25;
      hence thesis by A14,A15,A16,Lm6;
    end;
    hence thesis;
  end;
end;
