reserve x,y for set,
        r,s for Real,
        n for Nat,
        V for RealLinearSpace,
        v,u,w,p for VECTOR of V,
        A,B for Subset of V,
        Af for finite Subset of V,
        I for affinely-independent Subset of V,
        If for finite affinely-independent Subset of V,
        F for Subset-Family of V,
        L1,L2 for Linear_Combination of V;

theorem
  for F be c=-linear Subset-Family of V st
      union F is affinely-independent finite
    holds Int ((center_of_mass V).:F) c= Int union F
  proof
    set B=center_of_mass V;
    let S be c=-linear Subset-Family of V such that
    A1: union S is affinely-independent finite;
    reconsider BS=B.:S as affinely-independent Subset of V by A1,Th29;
    set U=union S;
    let x be object such that
    A2: x in Int(B.:S);
    BS is non empty by A2;
    then consider y being object such that
    A3: y in BS;
    consider X be object such that
    A4: X in dom B and
    A5: X in S and
    B.X=y by A3,FUNCT_1:def 6;
    reconsider X as set by TARSKI:1;
    X c=U & X is non empty by A4,A5,ZFMISC_1:56,74;
    then reconsider U as non empty finite Subset of V by A1;
    set xBS=x|--BS;
    A6: Int BS c=conv BS by Lm2;
    then A7: xBS is convex by A2,RLAFFIN1:71;
    S c=bool U
    proof
      let s be object;
       reconsider ss=s as set by TARSKI:1;
      assume s in S;
      then ss c=U by ZFMISC_1:74;
      hence thesis;
    end;
    then A8: U in S by A5,SIMPLEX0:9;
    dom B=(bool the carrier of V)\{{}} by FUNCT_2:def 1;
    then U in dom B by ZFMISC_1:56;
    then A9: B.U in BS by A8,FUNCT_1:def 6;
    then reconsider BU=B.U as Element of V;
    conv BS c=Affin BS by RLAFFIN1:65;
    then A10: Int BS c=Affin BS by A6;
    then A11: Sum xBS=x by A2,RLAFFIN1:def 7;
    then Carrier xBS=BS by A2,A6,Th11,RLAFFIN1:71;
    then A12: xBS.BU<>0 by A9,RLVECT_2:19;
    then A13: xBS.BU>0 by A2,A6,RLAFFIN1:71;
    set xU=x|--U;
    A14: conv U c=Affin U by RLAFFIN1:65;
    A15: conv(B.:S)c=conv U by Th17,CONVEX1:30;
    then A16: Int BS c=conv U by A6;
    then Int BS c=Affin U by A14;
    then A17: Sum xU=x by A1,A2,RLAFFIN1:def 7;
    BS c=conv BS by RLAFFIN1:2;
    then A18: B.U in conv BS by A9;
    per cases;
    suppose x=B.U;
      hence thesis by A1,Th20;
    end;
    suppose x<>BU;
      then consider p be Element of V such that
      A19: p in conv(BS\{BU}) and
      A20: Sum xBS=xBS.BU*BU+(1-xBS.BU)*p and
      1/xBS.BU*(Sum xBS)+(1-1/xBS.BU)*p=BU by A7,A11,A12,Th1;
      A21: x=(1-xBS.BU)*p+xBS.BU*BU by A2,A10,A20,RLAFFIN1:def 7;
      xBS.BU<=1 by A2,A6,RLAFFIN1:71;
      then A22: 1-xBS.BU>=1-1 by XREAL_1:10;
      A23: BU in conv U by A15,A18;
      conv(BS\{BU})c=conv BS by RLAFFIN1:3,XBOOLE_1:36;
      then A24: p in conv BS by A19;
      then p in conv U by A15;
      then A25: xU=(1-xBS.BU)*(p|--U)+xBS.BU*(BU|--U)
        by A1,A14,A21,A23,RLAFFIN1:70;
      A26: U c=Carrier xU
      proof
        let u be object;
        assume A27: u in U;
        then A28: xU.u=((1-xBS.BU)*(p|--U)).u+(xBS.BU*(BU|--U)).u
          by A25,RLVECT_2:def 10
        .=((1-xBS.BU)*(p|--U)).u+xBS.BU*((BU|--U).u) by A27,RLVECT_2:def 11
        .=(1-xBS.BU)*((p|--U).u)+xBS.BU*((BU|--U).u) by A27,RLVECT_2:def 11;
        (BU|--U).u=1/card U & (p|--U).u>=0 by A1,A15,A24,A27,Th18,RLAFFIN1:71;
        hence thesis by A13,A22,A27,A28;
      end;
      Carrier xU c=U by RLVECT_2:def 6;
      then Carrier xU=U by A26;
      hence thesis by A1,A2,A16,A17,Th12,RLAFFIN1:71;
    end;
  end;
