reserve X,Y,Z,Z1,Z2,D for set,x,y for object;
reserve SFX,SFY,SFZ for set;

theorem
  meet DIFFERENCE (SFX,SFY) c= meet SFX \ meet SFY
proof
  per cases;
  suppose
A1: SFX = {} or SFY = {};
    now
      assume DIFFERENCE (SFX,SFY) <> {};
      then consider e being object such that
A2:   e in DIFFERENCE (SFX,SFY) by XBOOLE_0:def 1;
      ex X,Y st X in SFX & Y in SFY & e = X \ Y by A2,Def6;
      hence contradiction by A1;
    end;
    then meet DIFFERENCE (SFX,SFY) = {} by Def1;
    hence thesis;
  end;
  suppose
A3: SFX <> {} & SFY <> {};
    set z = the Element of SFX;
    set y = the Element of SFY;
    let x be object such that
A4: x in meet DIFFERENCE (SFX,SFY);
    for Z st Z in SFX holds x in Z
    proof
      let Z;
      assume Z in SFX;
      then Z \ y in DIFFERENCE (SFX,SFY) by A3,Def6;
      then x in Z \ y by A4,Def1;
      hence thesis;
    end;
    then
A5: x in meet SFX by A3,Def1;
    z \ y in DIFFERENCE(SFX,SFY) by A3,Def6;
    then x in z \ y by A4,Def1;
    then not x in y by XBOOLE_0:def 5;
    then not x in meet SFY by A3,Def1;
    hence thesis by A5,XBOOLE_0:def 5;
  end;
end;
