reserve n,m,k,k1,k2,i,j for Nat;
reserve x,y,z for object,X,Y,Z for set;
reserve A for Subset of X;
reserve B,A1,A2,A3 for SetSequence of X;
reserve Si for SigmaField of X;
reserve S,S1,S2,S3 for SetSequence of Si;

theorem Th30:
 for n being Element of NAT holds
  (inferior_setsequence B).n = ((superior_setsequence Complement B ).n)`
proof let n be Element of NAT;
  set Y1 = {B.k1: n <= k1};
  set Y2 = {(Complement B).k2 : n <= k2};
  set Y3 = {(B.k)` where k is Element of NAT: n <= k};
A1: Y3 c= Y2
  proof
    let y be object;
    assume y in Y3;
    then consider k being Element of NAT such that
A2: y = (B.k)` and
A3: n <= k;
    y = (Complement B).k by A2,PROB_1:def 2;
    hence thesis by A3;
  end;
  Y2 c= Y3
  proof
    let x be object;
    assume x in Y2;
    then consider k such that
A4: x = (Complement B).k and
A5: n <= k;
    reconsider k as Element of NAT by ORDINAL1:def 12;
    x = (B.k)` by A4,PROB_1:def 2;
    hence thesis by A5;
  end;
  then
A6: Y2 = Y3 by A1,XBOOLE_0:def 10;
A7: Y1 <> {} by Th1;
  reconsider Y1 as Subset-Family of X by Th28;
A8: COMPLEMENT Y1 c= Y3
  proof
    let y be object;
    assume
A9: y in COMPLEMENT Y1;
    then reconsider y as Subset of X;
    y` in Y1 by A9,SETFAM_1:def 7;
    then consider k such that
A10: y` = B.k and
A11: n <= k;
    reconsider k as Element of NAT by ORDINAL1:def 12;
    y = (B.k)` by A10;
    hence thesis by A11;
  end;
  Y3 c= COMPLEMENT Y1
  proof
    let x be object;
    assume x in Y3;
    then consider k being Element of NAT such that
A12: x = (B.k)` and
A13: n <= k;
    reconsider z = B.k as Subset of X;
    (z`)` in Y1 by A13;
    hence thesis by A12,SETFAM_1:def 7;
  end;
  then Y3 = COMPLEMENT Y1 by A8,XBOOLE_0:def 10;
  then
  (superior_setsequence(Complement B)).n = union COMPLEMENT Y1 by A6,Def3
    .= [#] X \ meet Y1 by A7,SETFAM_1:34
    .= (meet Y1)`;
  hence thesis by Def2;
end;
