reserve n for Nat,
  i for Integer,
  p, x, x0, y for Real,
  q for Rational,
  f for PartFunc of REAL,REAL;

theorem Th30:
  for f be PartFunc of REAL,REAL, Z be Subset of REAL, Z1 be open
Subset of REAL st Z1 c= Z for n be Nat st f is_differentiable_on n,Z
  holds diff(f,Z).n | Z1 = diff(f,Z1).n
proof
  let f be PartFunc of REAL,REAL;
  let Z be Subset of REAL;
  let Z1 be open Subset of REAL such that
A1: Z1 c= Z;
  defpred P[Nat] means
f is_differentiable_on $1,Z implies diff(f,Z
  ).$1 | Z1 = diff(f,Z1).$1;
A2: for k be Nat st P[k] holds P[k+1]
  proof
    let k be Nat such that
A3: P[k];
    assume
A4: f is_differentiable_on (k+1), Z;
A5: (diff(f,Z).k) is_differentiable_on Z by A4;
    then
A6: (diff(f,Z).k) is_differentiable_on Z1 by A1,FDIFF_1:26;
    then
A7: dom((diff(f,Z).k)`| Z1) = Z1 by FDIFF_1:def 7;
A8: dom(((diff(f,Z).k)`|Z)| Z1) =dom((diff(f,Z).k)`|Z) /\ Z1 by RELAT_1:61
      .=Z /\ Z1 by A5,FDIFF_1:def 7
      .=Z1 by A1,XBOOLE_1:28;
A9: now
      let x be Element of REAL such that
A10:  x in dom(((diff(f,Z).k)`|Z)| Z1);
      thus (((diff(f,Z).k)`|Z)| Z1).x =((diff(f,Z).k)`|Z).x by A8,A10,
FUNCT_1:49
        .=diff((diff(f,Z).k),x) by A1,A5,A8,A10,FDIFF_1:def 7
        .=((diff(f,Z).k)`|Z1).x by A6,A8,A10,FDIFF_1:def 7;
    end;
    thus diff(f,Z).(k+1) | Z1 =((diff(f,Z).k)`|Z)| Z1 by Def5
      .=(diff(f,Z).k)`| Z1 by A8,A7,A9,PARTFUN1:5
      .=(diff(f,Z1).k)`| Z1 by A3,A4,A6,Th23,FDIFF_2:16,NAT_1:11
      .=diff(f,Z1).(k+1) by Def5;
  end;
A11: P[0]
  proof
    assume f is_differentiable_on 0, Z;
    thus (diff(f,Z).0) |Z1 =(f|Z)|Z1 by Def5
      .=f|Z1 by A1,FUNCT_1:51
      .=diff(f,Z1).0 by Def5;
  end;
  thus for k be Nat holds P[k] from NAT_1: sch 2(A11,A2);
end;
