reserve R for non empty RelStr,
  N for net of R,
  i for Element of N;

theorem Th30:
  for R being complete LATTICE, Z be net of R, D be Subset of R st
  D = the set of all "/\"({Z.k where k is Element of Z: k >= j},R)
  where j is Element of Z holds D is non empty directed
proof
  let R be complete LATTICE, Z be net of R, D be Subset of R;
  assume
A1: D = the set of all "/\"({Z.k where k is Element of Z: k >= j},R)
  where j is Element of Z;
  set j = the Element of Z;
  "/\"({Z.k where k is Element of Z: k >= j},R) in D by A1;
  hence D is non empty;
  let x,y be Element of R;
  assume x in D;
  then consider jx being Element of Z such that
A2: x = "/\"({Z.k where k is Element of Z: k >= jx},R) by A1;
  assume y in D;
  then consider jy being Element of Z such that
A3: y = "/\"({Z.k where k is Element of Z: k >= jy},R) by A1;
  reconsider jx, jy as Element of Z;
  consider j being Element of Z such that
A4: j >= jx and
A5: j >= jy by YELLOW_6:def 3;
  set E1 = {Z.k where k is Element of Z: k >= jx},
  Ey = {Z.k where k is Element of Z: k >= jy},
  E = {Z.k where k is Element of Z: k >= j};
  take z = "/\"({Z.k where k is Element of Z: k >= j},R);
  thus z in D by A1;
  E c= E1
  proof
    let e be object;
    assume e in E;
    then consider k being Element of Z such that
A6: e = Z.k and
A7: k >= j;
    reconsider k as Element of Z;
    k >= jx by A4,A7,YELLOW_0:def 2;
    hence thesis by A6;
  end;
  hence x <= z by A2,WAYBEL_7:1;
  E c= Ey
  proof
    let e be object;
    assume e in E;
    then consider k being Element of Z such that
A8: e = Z.k and
A9: k >= j;
    reconsider k as Element of Z;
    k >= jy by A5,A9,YELLOW_0:def 2;
    hence thesis by A8;
  end;
  hence y <= z by A3,WAYBEL_7:1;
end;
