
theorem Th30:
  for L being complete LATTICE, k being kernel Function of L,L holds
  k is directed-sups-preserving iff corestr k is directed-sups-preserving
proof
  let L be complete LATTICE, k be kernel Function of L,L;
  set ck = corestr k;
  [ck, inclusion k] is Galois by WAYBEL_1:39;
  then
A1: inclusion k is lower_adjoint;
A2: k = (inclusion k)*ck by WAYBEL_1:32;
  hereby
    assume
A3: k is directed-sups-preserving;
    thus corestr k is directed-sups-preserving
    proof
      let D be Subset of L;
      assume D is non empty directed;
      then
A4:   k preserves_sup_of D by A3;
      assume ex_sup_of D, L;
      then
A5:   sup (k.:D) = k.sup D by A4
        .= (inclusion k).(ck.sup D) by A2,FUNCT_2:15
        .= ck.sup D by FUNCT_1:18;
      thus ex_sup_of ck.:D, Image k by YELLOW_0:17;
A6:   ex_sup_of (inclusion k).:(ck.:D), L by YELLOW_0:17;
A7:   Image k is sups-inheriting by WAYBEL_1:53;
      ex_sup_of ck.:D, L by YELLOW_0:17;
      then
A8:   "\/"((ck.:D), L) in the carrier of Image k by A7;
      ck.:D = (inclusion k).:(ck.:D) by WAYBEL15:12;
      hence sup (ck.:D) = sup ((inclusion k).:(ck.:D)) by A6,A8,YELLOW_0:64
        .= ck.sup D by A2,A5,RELAT_1:126;
    end;
  end;
  thus thesis by A1,A2,WAYBEL15:11;
end;
