reserve i for Nat, x,y for set;
reserve S for non empty non void ManySortedSign;
reserve X for non-empty ManySortedSet of S;

theorem Th26:
  for S being non void non empty ManySortedSign
  for o being OperSymbol of S
  for r being SortSymbol of S st o is_of_type {}, r
  for A being MSAlgebra over S
  st (the Sorts of A).r <> {}
  holds Den(In(o, the carrier' of S), A).{} is
        Element of (the Sorts of A).r
  proof
    let S be non void non empty ManySortedSign;
    let o be OperSymbol of S;
    let r be SortSymbol of S;
    assume
A1: (the Arity of S).o = {} & (the ResultSort of S).o = r;
    reconsider s = o as OperSymbol of S;
    let A be MSAlgebra over S;
    assume A3: (the Sorts of A).r <> {};
A4: <*>the carrier of S in (the carrier of S)* by FINSEQ_1:def 11;
    ((the Sorts of A)#*the Arity of S).o
    = (the Sorts of A)#.{} by A1,FUNCT_2:15
    .= product ((the Sorts of A)*{}) by A4,FINSEQ_2:def 5
    .= product {}; then
A5: {} in Args(s, A) by CARD_3:10,TARSKI:def 1;
    Result(s, A) = (the Sorts of A).the_result_sort_of s by FUNCT_2:15;
    hence Den(In(o, the carrier' of S), A).{} is
    Element of (the Sorts of A).r by A1,A3,A5,FUNCT_2:5;
  end;
