reserve X for non empty set;
reserve Y for ComplexLinearSpace;
reserve f,g,h for Element of Funcs(X,the carrier of Y);
reserve a,b for Complex;
reserve u,v,w for VECTOR of CLSStruct(#Funcs(X,the carrier of Y), (FuncZero(X,
    Y)),FuncAdd(X,Y),FuncExtMult(X,Y)#);

theorem Th31:
  for X,Y be ComplexNormSpace,
  f being Point of C_NormSpace_of_BoundedLinearOperators(X,Y),
  g be Lipschitzian LinearOperator of X,Y
  st g=f holds for t be VECTOR of X holds ||.g.t.|| <= ||.f.|| * ||.t.||
proof
  let X,Y be ComplexNormSpace;
  let f being Point of C_NormSpace_of_BoundedLinearOperators(X,Y);
  let g be Lipschitzian LinearOperator of X,Y such that
A1: g=f;
A2: PreNorms(g) is non empty bounded_above by Th26;
  now
    let t be VECTOR of X;
    now
      per cases;
      case
A3:     t = 0.X;
        then
A4:     ||.t.|| = 0 by NORMSP_0:def 6;
        g.t =g.(0c * 0.X) by A3,CLVECT_1:1
          .=0c * g.(0.X) by Def3
          .=0.Y by CLVECT_1:1;
        hence ||.g.t.|| <= ||.f.||*||.t.|| by A4,NORMSP_0:def 6;
      end;
      case
A5:     t <> 0.X;
        reconsider t0 = ||.t.||"+0*<i> as Element of COMPLEX by XCMPLX_0:def 2;
        reconsider t1= t0*t as VECTOR of X;
A6:     ||.t.|| <> 0 by A5,NORMSP_0:def 5;
        then
A7:     ||.t.|| > 0 by CLVECT_1:105;
A8:     |. t0 .| =|. 1*||.t.||" .| .=|. 1/||.t.||.| by XCMPLX_0:def 9
          .=1/|. ||.t.||.| by ABSVALUE:7
          .=1/||.t.|| by A7,ABSVALUE:def 1
          .=1*||.t.||" by XCMPLX_0:def 9
          .=||.t.||";
        then
A9:     ||.g.t.||/||.t.|| =||.g.t.|| * |. t0 .| by XCMPLX_0:def 9
          .=||.t0*g.t.|| by CLVECT_1:def 13
          .=||.g.t1.|| by Def3;
        ||.t1.|| = |.t0.| * ||.t.|| by CLVECT_1:def 13
          .=1 by A6,A8,XCMPLX_0:def 7;
        then ||.g.t.||/||.t.|| in {||.g.s.|| where s is VECTOR of X : ||.s.||
        <= 1 } by A9;
        then ||.g.t.||/||.t.|| <= upper_bound PreNorms(g) by A2,SEQ_4:def 1;
        then ||.g.t.||/||.t.|| <= BoundedLinearOperatorsNorm(X,Y).g by Th29;
        then
A10:    ||.g.t.||/||.t.|| <= ||.f.|| by A1;
        ||.g.t.||/||.t.||*||.t.|| = ||.g.t.||*||.t.||"*||.t.|| by
XCMPLX_0:def 9
          .=||.g.t.||*(||.t.||"*||.t.||)
          .=||.g.t.||*1 by A6,XCMPLX_0:def 7
          .=||.g.t.||;
        hence ||.g.t.|| <= ||.f.||*||.t.|| by A7,A10,XREAL_1:64;
      end;
    end;
    hence ||.g.t.|| <= ||.f.||*||.t.||;
  end;
  hence thesis;
end;
