reserve x for Real,

  Z for open Subset of REAL;

theorem
  Z c= dom (sin(#)(sin+cos)) implies sin(#)(sin+cos)
is_differentiable_on Z & for x st x in Z holds ((sin(#)(sin+cos))`|Z).x =(cos.x
  )^2+2*sin.x*cos.x-(sin.x)^2
proof
A1: for x st x in Z holds sin is_differentiable_in x by SIN_COS:64;
  assume
A2: Z c= dom (sin(#)(sin+cos));
  then
A3: Z c= dom (sin+cos) /\ dom sin by VALUED_1:def 4;
  then
A4: Z c= dom (sin+cos) by XBOOLE_1:18;
  then
A5: sin+cos is_differentiable_on Z by FDIFF_7:38;
  Z c= dom sin by A3,XBOOLE_1:18;
  then
A6: sin is_differentiable_on Z by A1,FDIFF_1:9;
  for x st x in Z holds ((sin(#)(sin+cos))`|Z).x =(cos.x)^2+2*sin.x*cos.x-
  (sin.x)^2
  proof
    let x;
     reconsider xx=x as Element of REAL by XREAL_0:def 1;
    assume
A7: x in Z;
    then ((sin(#)(sin+cos))`|Z).x =((sin+cos).x)*diff(sin,x) + (sin.x)*diff((
    sin+cos),x) by A2,A5,A6,FDIFF_1:21
      .=(sin.xx+cos.xx)*diff(sin,x) + (sin.x)*diff((sin+cos),x)
            by VALUED_1:1
      .=(sin.x+cos.x)*cos.x + (sin.x)*diff((sin+cos),x) by SIN_COS:64
      .=(sin.x+cos.x)*cos.x + (sin.x)*((sin+cos)`|Z).x by A5,A7,FDIFF_1:def 7
      .=(sin.x+cos.x)*cos.x + (sin.x)*(cos.x-sin.x) by A4,A7,FDIFF_7:38;
    hence thesis;
  end;
  hence thesis by A2,A5,A6,FDIFF_1:21;
end;
