reserve x, y, X for set;
reserve E for non empty set;
reserve e for Element of E;
reserve u, u1, v, v1, v2, w, w9, w1, w2 for Element of E^omega;
reserve F for Subset of E^omega;
reserve i, k, l for Nat;
reserve TS for non empty transition-system over F;
reserve S, T for Subset of TS;
reserve SA for non empty semiautomaton over F;
reserve A for non empty automaton over F;
reserve p, q for Element of A;
reserve TS for non empty transition-system over Lex(E) \/ {<%>E};

theorem Th31:
  w-succ_of ({ v-succ_of (X, TS) }, _bool TS) = { v^w-succ_of (X, TS) }
proof
  defpred P[Nat] means len u <= $1 implies for v holds u-succ_of({ v-succ_of (
  X, TS) }, _bool TS) = { v^u-succ_of (X, TS) };
A1: not <%>E in rng dom (the Tran of _bool TS) by Th8;
A2: P[0]
  proof
    let u;
    assume len u <= 0;
    then
A3: u = <%>E;
    let v;
    reconsider vso = { v-succ_of (X, TS) } as Subset of _bool TS by Def1;
  u-succ_of (vso, _bool TS) = vso by A1,A3,REWRITE3:104;
    hence u-succ_of({ v-succ_of (  X, TS) }, _bool TS)
       = { v^{}-succ_of (X, TS) }
      .= { v^{}-succ_of (X, TS) }
      .= { v^u-succ_of (X, TS) } by A3;
  end;
A4: now
    let k;
    assume
A5: P[k];
    now
      let u;
      assume
A6:   len u <= k + 1;
      let v;
      per cases;
      suppose
A7:     k = 0;
        per cases by A6,A7,NAT_1:25;
        suppose
          len u = 0;
          hence
          u-succ_of ({ v-succ_of (X, TS) }, _bool TS) = { v^u-succ_of (X,
          TS) } by A2;
        end;
        suppose
A8:       len u = 1;
A9:       now
            let x be object;
            assume
A10:        x in { v^u-succ_of (X, TS) };
            then reconsider P = x as Element of _bool TS by Def1;
            x = v^u-succ_of (X, TS) by A10,TARSKI:def 1;
            then x = u-succ_of (v-succ_of (X, TS), TS) by Th29;
            then
A11:        v-succ_of (X, TS), u ==>* x, _bool TS by A8,Th13;
            v-succ_of (X, TS) is Element of _bool TS & v-succ_of (X, TS)
            in { v-succ_of (X, TS) } by Def1,TARSKI:def 1;
            then P in u-succ_of ( { v-succ_of (X, TS) }, _bool TS) by A11,
REWRITE3:103;
            hence x in u-succ_of ( { v-succ_of (X, TS) }, _bool TS);
          end;
          now
            let x be object;
            assume
A12:        x in u-succ_of ({ v-succ_of (X, TS) }, _bool TS);
            then reconsider P = x as Element of _bool TS;
            consider Q being Element of _bool TS such that
A13:        Q in { v-succ_of (X, TS) } & Q, u ==>* P, _bool TS by A12,
REWRITE3:103;
            Q = v-succ_of (X, TS) & P = u-succ_of (Q, TS) by A8,A13,Th13,
TARSKI:def 1;
            then P = v^u-succ_of (X, TS) by Th29;
            hence x in { v^u-succ_of (X, TS) } by TARSKI:def 1;
          end;
          hence
          u-succ_of ({ v-succ_of (X, TS) }, _bool TS) = { v^u-succ_of (X,
          TS) } by A9,TARSKI:2;
        end;
      end;
      suppose
A14:    k <> 0;
        reconsider bTS = _bool TS as non empty transition-system over Lex(E)
        \/ {<%>E} by Th30;
        consider v1, v2 such that
A15:    len v1 <= k and
A16:    len v2 <= k and
A17:    u = v1^v2 by A6,A14,Th5;
A18:    v1-succ_of({ v-succ_of(X, TS) }, _bool TS) = { v^v1-succ_of (X,
        TS) } by A5,A15;
A19:    the Tran of bTS = the Tran of _bool TS;
        then
        v1^v2-succ_of ({ v-succ_of (X, TS) }, _bool TS) = v1^v2-succ_of (
        { v-succ_of (X, TS) }, bTS) by REWRITE3:105
          .= v2-succ_of (v1-succ_of ({ v-succ_of (X, TS) }, bTS), bTS) by Th29
          .= v2-succ_of (v1-succ_of ({ v-succ_of (X, TS) }, _bool TS), bTS)
        by A19,REWRITE3:105
          .= v2-succ_of(v1-succ_of({ v-succ_of (X, TS) }, _bool TS), _bool
        TS) by A19,REWRITE3:105
          .= { v^v1^v2-succ_of (X, TS) } by A5,A16,A18
          .= { v^(v1^v2)-succ_of (X, TS) } by AFINSQ_1:27;
        hence u-succ_of ({ v-succ_of (X, TS) }, _bool TS) = { v^u-succ_of (X,
        TS) } by A17;
      end;
    end;
    hence P[k + 1];
  end;
  for k holds P[k] from NAT_1:sch 2(A2, A4);
  then len w <= len w implies w-succ_of ({ v-succ_of (X, TS) }, _bool TS) = {
  v^w-succ_of (X, TS) };
  hence thesis;
end;
