reserve i,j,k for Nat,
  r,s,r1,r2,s1,s2,sb,tb for Real,
  x for set,
  GX for non empty TopSpace;
reserve GZ for non empty TopSpace;
reserve f for non constant standard special_circular_sequence,
  G for non empty-yielding Matrix of TOP-REAL 2;
reserve G for non empty-yielding X_equal-in-line Y_equal-in-column Matrix of
  TOP-REAL 2;

theorem Th31:
  1 <= i & i < len G implies cell(G,i,width G) = { |[r,s]|: G*(i,1
  )`1 <= r & r <= G*(i+1,1)`1 & G*(1,width G)`2 <= s }
proof
A1: cell(G,i,width G) = v_strip(G,i) /\ h_strip(G,width G) by GOBOARD5:def 3;
  assume 1 <= i & i < len G;
  then
A2: v_strip(G,i) = { |[r,s]| : G*(i,1)`1 <= r & r <= G* (i+1,1)`1 } by Th20;
A3: h_strip(G,width G) = { |[r,s]| : G*(1,width G)`2 <= s } by Th22;
  thus cell(G,i,width G) c= { |[r,s]| : G*(i,1)`1 <= r & r <= G*(i+1,1)`1 & G*
  (1,width G)`2 <= s }
  proof
    let x be object;
    assume
A4: x in cell(G,i,width G);
    then x in v_strip(G,i) by A1,XBOOLE_0:def 4;
    then consider r1,s1 such that
A5: x = |[r1,s1]| and
A6: G*(i,1)`1 <= r1 & r1 <= G*(i+1,1)`1 by A2;
    x in h_strip(G,width G) by A1,A4,XBOOLE_0:def 4;
    then consider r2,s2 such that
A7: x = |[r2,s2]| and
A8: G*(1,width G)`2 <= s2 by A3;
    s1 = s2 by A5,A7,SPPOL_2:1;
    hence thesis by A5,A6,A8;
  end;
  let x be object;
  assume x in { |[r,s]| : G*(i,1)`1 <= r & r <= G*(i+1,1)`1 & G* (1,width G)
  `2 <= s };
  then
A9: ex r,s st x = |[r,s]| & G*(i,1)`1 <= r & r <= G*(i+1,1)`1 & G*(1,width
  G)`2 <= s;
  then
A10: x in h_strip(G,width G) by A3;
  x in v_strip(G,i) by A2,A9;
  hence thesis by A1,A10,XBOOLE_0:def 4;
end;
