reserve i, j, n for Nat,
  f for non constant standard special_circular_sequence,
  g for clockwise_oriented non constant standard special_circular_sequence,
  p, q for Point of TOP-REAL 2,
  P for Subset of TOP-REAL 2,
  C for compact non vertical non horizontal Subset of TOP-REAL 2,
  G for Go-board;
reserve f for clockwise_oriented non constant standard
  special_circular_sequence;

theorem Th31:
  RightComp g c= RightComp SpStSeq L~g
proof
  let a be object;
  assume
A1: a in RightComp g;
  then reconsider p = a as Point of TOP-REAL 2;
  p`1 > W-bound L~g by A1,Th23;
  then
A2: p`1 > W-bound L~SpStSeq L~g by SPRECT_1:58;
  p`2 > S-bound L~g by A1,Th26;
  then
A3: p`2 > S-bound L~SpStSeq L~g by SPRECT_1:59;
  p`1 < E-bound L~g by A1,Th24;
  then
A4: p`1 < E-bound L~SpStSeq L~g by SPRECT_1:61;
  p`2 < N-bound L~g by A1,Th25;
  then
A5: p`2 < N-bound L~SpStSeq L~g by SPRECT_1:60;
  RightComp SpStSeq L~g = {q : W-bound L~SpStSeq L~g < q`1 & q`1 <
  E-bound L~SpStSeq L~g & S-bound L~SpStSeq L~g < q`2 & q`2 < N-bound L~SpStSeq
  L~g} by SPRECT_3:37;
  hence thesis by A2,A4,A3,A5;
end;
