reserve Al for QC-alphabet;
reserve b,c,d for set,
  X,Y for Subset of CQC-WFF(Al),
  i,j,k,m,n for Nat,
  p,p1,q,r,s,s1 for Element of CQC-WFF(Al),
  x,x1,x2,y,y1 for bound_QC-variable of Al,
  A for non empty set,
  J for interpretation of Al, A,
  v for Element of Valuations_in(Al,A),
  f1,f2 for FinSequence of CQC-WFF(Al),
  CX,CY,CZ for Consistent Subset of CQC-WFF(Al),
  JH for Henkin_interpretation of CX,
  a for Element of A,
  t,u for QC-symbol of Al;
reserve L for PATH of q,p,
  F1,F3 for QC-formula of Al,
  a for set;
reserve C,D for Element of [:CQC-WFF(Al),bool bound_QC-variables(Al):];
reserve K,L for Subset of bound_QC-variables(Al);

theorem Th31:
  ( Al is countable &
  still_not-bound_in CX is finite ) implies
  ex CY st CX c= CY & CY is with_examples
proof
  assume A1: Al is countable;
  assume
A2: still_not-bound_in CX is finite;
  ExCl(Al) is non empty & ExCl(Al) is countable by A1,Th20;
  then consider f being Function such that
A3: dom f = NAT and
A4: ExCl(Al) = rng f by Lm1;
  reconsider f as sequence of CQC-WFF(Al) by A3,A4,FUNCT_2:2;
  defpred P[Nat,set,set] means
  ex K,L st K = $2`2 & L = K \/ still_not-bound_in {f.($1+1)} &
  $3 = [('not' (f.($1+1))) 'or' (the_scope_of(f,($1+1)).(bound_in(f,$1+1),
  x.(Al-one_in {t : not x.t in L}))), K \/ still_not-bound_in
  ('not' (f.($1+1))) 'or' (the_scope_of(f,($1+1)).(bound_in(f,$1+1),
  x.(Al-one_in {u : not x.u in L})))];
A5: for n being Nat for C ex D st P[n,C,D]
  proof
    let n be Nat,C;
    set K = C`2;
    ex a,b being object st
( a in CQC-WFF(Al))&( b in bool bound_QC-variables(Al))&(
    C = [a,b]) by ZFMISC_1:def 2;
    then reconsider K as Subset of bound_QC-variables(Al);
    set L = K \/ still_not-bound_in {f.(n+1)};
    set D = [('not' (f.(n+1))) 'or' (the_scope_of(f,(n+1)).(bound_in(f,n+1),
    x.(Al-one_in {t : not x.t in L}))), K \/ still_not-bound_in
    ('not' (f.(n+1))) 'or' (the_scope_of(f,(n+1)).(bound_in(f,n+1),
    x.(Al-one_in {u : not x.u in L})))];
    take D;
    thus thesis;
  end;
  reconsider A = [('not' (f.0)) 'or' (the_scope_of(f,0).(bound_in(f,0),
  x.(Al-one_in {u : not x.u in still_not-bound_in (CX \/ {f.0})}))),
  still_not-bound_in (CX \/ {('not' (f.0)) 'or'
  (the_scope_of(f,0).(bound_in(f,0), x.(Al-one_in {t :
  not x.t in still_not-bound_in (CX \/ {f.0})})))})]
  as Element of [:CQC-WFF(Al),bool bound_QC-variables(Al):];
  consider h being sequence of [:CQC-WFF(Al),bool bound_QC-variables(Al):]
  such that
A6: h.0 = A &
   for n being Nat holds P[n,h.n,h.(n+1)] from RECDEF_1:sch 2(A5);
  set CY = CX \/ the set of all (h.n)`1 ;
  now
    let a be object such that
A7: a in CY;
    now
      assume not a in CX;
      then a in the set of all (h.n)`1  by A7,XBOOLE_0:def 3;
      then consider n such that
A8:   a = (h.n)`1;
      ex c,d being object st
( c in CQC-WFF(Al))&( d in bool bound_QC-variables(Al))&(
      h.n = [c,d]) by ZFMISC_1:def 2;
      hence a in CQC-WFF(Al) by A8;
    end;
    hence a in CQC-WFF(Al);
  end;
  then reconsider CY as Subset of CQC-WFF(Al) by TARSKI:def 3;
A9: now
    let x,p;
    Ex(x,p) in ExCl(Al) by Def3;
    then consider a being object such that
A10: a in dom f and
A11: f.a = Ex(x,p) by A4,FUNCT_1:def 3;
    reconsider a as Nat by A10;
    reconsider r9 = f.a as Element of CQC-WFF(Al);
A12: Ex-bound_in r9 = x by A11,Th22;
A13: Ex-the_scope_of r9 = p by A11,Th22;
A14: bound_in(f,a) = x by A12,Def6;
A15: the_scope_of(f,a) = p by A13,Def7;
A16: (h.a)`1 in the set of all (h.n)`1 ;
A17: the set of all (h.n)`1  c= CY by XBOOLE_1:7;
A18: a = 0 implies ex y being bound_QC-variable of Al
      st CY |- 'not' Ex(x,p) 'or' (p.(x,y)) by A6,A11,A14,A15,A16,A17,Th21;
    now
      assume a <> 0;
      then consider m being Nat such that
A20:  a = m+1 by NAT_1:6;
      reconsider m as Nat;
A21:  ex K,L st K = (h.m)`2 & L = K \/ still_not-bound_in {r9} &
      h.a = [('not' r9) 'or' (the_scope_of(f,a).(bound_in(f,a),
      x.(Al-one_in {t : not x.t in L}))), K \/ still_not-bound_in
      ('not' r9) 'or' (the_scope_of(f,a).(bound_in(f,a),
      x.(Al-one_in {u : not x.u in L})))] by A6,A20;
      set K = (h.m)`2;
      set L = still_not-bound_in ({r9}) \/ K;
      take y = x.(Al-one_in {t : not x.t in L});
      (h.a)`1 = 'not' r9 'or' (the_scope_of(f,a).(bound_in(f,a),y))
      by A21;
      hence CY |- ('not' Ex(x,p)) 'or' (p.(x,y)) by A11,A14,A15,A16,A17,Th21;
    end;
    hence ex y st CY |- 'not' Ex(x,p) 'or' (p.(x,y)) by A18;
  end;
  deffunc G(set) = CX \/ {(h.n)`1 : n in $1};
  consider F being Function such that
A22: dom F = NAT &
for a st a in NAT holds F.a = G(a) from FUNCT_1:sch 5;
A23: CY c= union rng F
  proof
    let a be object;
    assume
A24: a in CY;
A25: now
      assume
A26:  a in CX;
A27:  F.0 = CX \/ {(h.n)`1 : n in 0} by A22;
      now
        let b be object;
        assume b in {(h.n)`1 : n in 0};
        then ex n st ( b = (h.n)`1)&( n in 0);
        hence contradiction;
      end;
      then
A28:  {(h.n)`1 : n in 0} = {} by XBOOLE_0:def 1;
      F.0 in rng F by A22,FUNCT_1:3;
      hence thesis by A26,A27,A28,TARSKI:def 4;
    end;
    now
      assume a in the set of all (h.n)`1 ;
      then consider n such that
A29:  a = (h.n)`1;
      n < n+1 by NAT_1:13;
      then n in Segm(n+1) by NAT_1:44;
      then
A30:  a in {(h.m)`1 : m in n+1} by A29;
      F.(n+1) = CX \/ {(h.m)`1 : m in n+1} by A22;
      then
A31:  {(h.m)`1 : m in n+1} c= F.(n+1) by XBOOLE_1:7;
      F.(n+1) in rng F by A22,FUNCT_1:3;
      hence thesis by A30,A31,TARSKI:def 4;
    end;
    hence thesis by A24,A25,XBOOLE_0:def 3;
  end;
  union rng F c= CY
  proof
    let a be object;
    assume a in union rng F;
    then consider b such that
A32: a in b and
A33: b in rng F by TARSKI:def 4;
    consider c being object such that
A34: c in dom F and
A35: F.c = b by A33,FUNCT_1:def 3;
    reconsider n = c as Element of NAT by A22,A34;
A36: a in CX \/ {(h.m)`1 : m in n} by A22,A32,A35;
A37: now
      assume
A38:  a in CX;
      CX c= CY by XBOOLE_1:7;
      hence thesis by A38;
    end;
    now
      assume a in {(h.m)`1 : m in n};
      then ex m st ( a = (h.m)`1)&( m in n);
      then
A39:  a in the set of all (h.i)`1 ;
      the set of all (h.i)`1  c= CY by XBOOLE_1:7;
      hence thesis by A39;
    end;
    hence thesis by A36,A37,XBOOLE_0:def 3;
  end;
  then
A40: CY = union rng F by A23;
A41: for n,m st m in dom F & n in dom F & n < m holds F.n c= F.m
  proof
    let n,m such that
    m in dom F and n in dom F and
A42: n < m;
    reconsider n,m as Element of NAT by ORDINAL1:def 12;
A43: F.n = CX \/ {(h.i)`1 : i in n} by A22;
A44: F.m = CX \/ {(h.i)`1 : i in m} by A22;
    now
      let a be object such that
A45:  a in F.n;
A46:  now
        assume
A47:    a in CX;
        CX c= F.m by A44,XBOOLE_1:7;
        hence a in F.m by A47;
      end;
      now
        assume a in {(h.i)`1 : i in n};
        then consider i such that
A48:    (h.i)`1 = a and
A49:    i in Segm n;
        i < n by A49,NAT_1:44;
        then i < m by A42,XXREAL_0:2;
        then i in Segm m by NAT_1:44;
        then
A50:    a in {(h.j)`1 : j in m} by A48;
        {(h.j)`1 : j in m} c= F.m by A44,XBOOLE_1:7;
        hence a in F.m by A50;
      end;
      hence a in F.m by A43,A45,A46,XBOOLE_0:def 3;
    end;
    hence thesis;
  end;
  rng F c= bool CQC-WFF(Al)
  proof
    let a be object;
    assume a in rng F;
    then consider b being object such that
A51: b in dom F and
A52: F.b = a by FUNCT_1:def 3;
    reconsider b as Element of NAT by A22,A51;
A53: F.b = CX \/ {(h.i)`1 : i in b} by A22;
    now
      let c be object;
      assume c in {(h.i)`1 : i in b};
      then ex i st ( (h.i)`1 = c)&( i in b);
      hence c in CQC-WFF(Al) by MCART_1:10;
    end;
    then {(h.i)`1 : i in b} c= CQC-WFF(Al);
    then F.b c= CQC-WFF(Al) by A53,XBOOLE_1:8;
    hence thesis by A52;
  end;
  then reconsider F as sequence of bool CQC-WFF(Al) by A22,FUNCT_2:2;
A54: for n holds F.(n+1) = F.n \/ {(h.n)`1}
  proof
    let n;
A55:  n in NAT by ORDINAL1:def 12;
    now
      let a be object;
      assume a in {(h.i)`1 : i in n+1};
      then consider j such that
A56:  a = (h.j)`1 and
A57:  j in Segm(n+1);
      j < n+1 by A57,NAT_1:44;
      then
A58:  j+1 <= n+1 by NAT_1:13;
A59:  now
        assume j+1 = n+1;
        then
A60:    a in {(h.n)`1} by A56,TARSKI:def 1;
        {(h.n)`1} c= {(h.i)`1 : i in n} \/ {(h.n)`1} by XBOOLE_1:7;
        hence a in {(h.i)`1 : i in n} \/ {(h.n)`1} by A60;
      end;
      now
        assume j+1 <= n;
        then j < n by NAT_1:13;
        then j in Segm n by NAT_1:44;
        then
A61:    a in {(h.k)`1 : k in n} by A56;
        {(h.k)`1 : k in n} c= {(h.i)`1 : i in n} \/ {(h.n)`1} by XBOOLE_1:7;
        hence a in {(h.i)`1 : i in n} \/ {(h.n)`1} by A61;
      end;
      hence a in {(h.i)`1 : i in n} \/ {(h.n)`1} by A58,A59,NAT_1:8;
    end;
    then
A62: {(h.k)`1 : k in n+1} c= {(h.i)`1 : i in n} \/ {(h.n)`1};
    now
      let a be object;
      assume
A63:  a in {(h.i)`1 : i in n} \/ {(h.n)`1};
A64:  now
        assume a in {(h.i)`1 : i in n};
        then consider j such that
A65:    (h.j)`1 = a and
A66:    j in Segm n;
A67:    n <= n+1 by NAT_1:11;
        j < n by A66,NAT_1:44;
        then j < n+1 by A67,XXREAL_0:2;
        then j in Segm(n+1) by NAT_1:44;
        hence a in {(h.i)`1 : i in n+1} by A65;
      end;
      now
        assume a in {(h.n)`1};
        then
A68:    a = (h.n)`1 by TARSKI:def 1;
        n < n+1 by NAT_1:13;
        then n in Segm(n+1) by NAT_1:44;
        hence a in {(h.i)`1 : i in n+1} by A68;
      end;
      hence a in {(h.i)`1 : i in n+1} by A63,A64,XBOOLE_0:def 3;
    end;
    then {(h.i)`1 : i in n} \/ {(h.n)`1} c= {(h.k)`1 : k in n+1};
    then {(h.i)`1 : i in n} \/ {(h.n)`1} = {(h.k)`1 : k in n+1}
    by A62;
    then F.(n+1) = CX \/ ({(h.k)`1 : k in n} \/ {(h.n)`1}) by A22;
    then F.(n+1) = G(n) \/ {(h.n)`1} by XBOOLE_1:4;
    hence F.(n+1) = F.n \/ {(h.n)`1} by A22,A55;
  end;
  defpred P[Nat] means (h.$1)`2 is finite &
  (h.$1)`2 is Subset of bound_QC-variables(Al);
A69: P[0]
  proof
A70: (h.0)`2 = still_not-bound_in (CX \/ {('not' (f.0)) 'or'
    (the_scope_of(f,0).(bound_in(f,0), x.(Al-one_in {t :
    not x.t in still_not-bound_in (CX \/ {f.0})})))}) by A6;
    reconsider s = ('not' (f.0)) 'or'
    (the_scope_of(f,0).(bound_in(f,0), x.(Al-one_in {t :
    not x.t in still_not-bound_in (CX \/ {f.0})})))
    as Element of CQC-WFF(Al);
    still_not-bound_in s is finite by CQC_SIM1:19;
    then still_not-bound_in {s} is finite by Th26;
    then still_not-bound_in {s} \/ still_not-bound_in CX is finite by A2;
    hence thesis by A70,Th27;
  end;
A71: for k st P[k] holds P[k+1]
  proof
    let k such that
A72: P[k];
A73: ex K,L st K = (h.k)`2 & L = K \/ still_not-bound_in {f.(k+1)} &
    h.(k+1) = [('not' (f.(k+1))) 'or' (the_scope_of(f,k+1).(bound_in(f,k+1),
    x.(Al-one_in {t : not x.t in L}))), K \/ still_not-bound_in
    ('not' (f.(k+1))) 'or' (the_scope_of(f,k+1).(bound_in(f,k+1),
    x.(Al-one_in {u : not x.u in L})))] by A6;
    set K = (h.k)`2;
    reconsider K as Subset of bound_QC-variables(Al) by A72;
    set L = K \/ still_not-bound_in {f.(k+1)};
    set s = ('not' (f.(k+1))) 'or' (the_scope_of(f,(k+1)).
    (bound_in(f,k+1),x.(Al-one_in {t : not x.t in L})));
    still_not-bound_in s is finite by CQC_SIM1:19;
    hence thesis by A72,A73;
  end;
A74: for k holds P[k] from NAT_1:sch 2(A69,A71);
  defpred P[Nat] means still_not-bound_in (F.($1+1)) c= (h.$1)`2 &
  not x.(Al-one_in {t : not x.t in still_not-bound_in
  {f.($1+1)} \/ (h.$1)`2}) in still_not-bound_in (F.($1+1) \/ {f.($1+1)});
A75: for k holds still_not-bound_in (F.(k+1)) c= (h.k)`2 & not x.(Al-one_in {t:
  not x.t in still_not-bound_in {f.(k+1)} \/ (h.k)`2})
  in still_not-bound_in (F.(k+1) \/ {f.(k+1)})
  proof
A76: P[0]
    proof
      set r = ('not' (f.0)) 'or'
      (the_scope_of(f,0).(bound_in(f,0), x.(Al-one_in {t :
      not x.t in still_not-bound_in (CX \/ {f.0})})));
      set A1 = {r};
      reconsider s = f.1 as Element of CQC-WFF(Al);
A77:  (h.0)`2 = still_not-bound_in (CX \/ A1) by A6;
      reconsider B = (h.0)`2 as Subset of bound_QC-variables(Al)
      by A6;
      reconsider C = still_not-bound_in {s} \/ B as Element of
      bool bound_QC-variables(Al);
      still_not-bound_in s is finite by CQC_SIM1:19;
      then still_not-bound_in {s} is finite by Th26;
      then consider x such that
A78:  not x in C by A69,Th28;
      consider u such that
A79:  x.u = x by QC_LANG3:30;
      u in {t : not x.t in C} by A78,A79;
      then reconsider A = {t : not x.t in C} as non empty set;
      now
        let a be object;
        assume a in A;
        then ex t st ( a = t)&( not x.t in C);
        hence a in QC-symbols(Al);
      end;
      then reconsider A={t:not x.t in C} as non empty Subset of QC-symbols(Al)
      by TARSKI:def 3;
      set u = Al-one_in A;
      u = the Element of A by QC_LANG1:def 41;
      then u in A;
      then
A80:  ex t st ( t = u)&( not x.t in C);
A81:  F.0 = CX \/ {(h.n)`1 : n in 0} by A22;
      now
        let b be object;
        assume b in {(h.n)`1 : n in 0};
        then ex n st ( b = (h.n)`1)&( n in 0);
        hence contradiction;
      end;
      then
A82:  {(h.n)`1 : n in 0} = {} by XBOOLE_0:def 1;
      (h.0)`1 = r by A6;
      then F.(0+1) = CX \/ {r} by A54,A81,A82;
      hence thesis by A77,A80,Th27;
    end;
A83: for k st P[k] holds P[k+1]
    proof
      let k such that
A84:  P[k];
      reconsider s = f.(k+2) as Element of CQC-WFF(Al);
A85:  ex K,L st K = (h.k)`2 & L = K \/ still_not-bound_in {f.(k+1)} &
      h.(k+1) = [('not' (f.(k+1))) 'or' (the_scope_of(f,(k+1)).
      (bound_in(f,k+1),x.(Al-one_in {t : not x.t in L}))),
      K \/ still_not-bound_in
      ('not' (f.(k+1))) 'or' (the_scope_of(f,k+1).(bound_in(f,k+1),
      x.(Al-one_in {u : not x.u in L})))] by A6;
      set K = (h.k)`2;
      reconsider K as Subset of bound_QC-variables(Al) by A74;
      set L = K \/ still_not-bound_in {f.(k+1)};
      set r = ('not' (f.(k+1))) 'or' (the_scope_of(f,(k+1)).
      (bound_in(f,k+1),x.(Al-one_in {t : not x.t in L})));
A86:  (h.(k+1))`1 = r by A85;
A87:  (h.(k+1))`2 = K \/ still_not-bound_in r by A85;
      reconsider B = (h.(k+1))`2 as Subset of bound_QC-variables(Al) by A85;
      reconsider C = still_not-bound_in {s} \/ B as Element of
      bool bound_QC-variables(Al);
      still_not-bound_in s is finite by CQC_SIM1:19;
      then
A88:  still_not-bound_in {s} is finite by Th26;
      (h.(k+1))`2 is finite by A74;
      then consider x such that
A89:  not x in C by A88,Th28;
      consider u such that
A90:  x.u = x by QC_LANG3:30;
      u in {t : not x.t in still_not-bound_in {s} \/ B} by A89,A90;
      then reconsider A = {t : not x.t in still_not-bound_in {s} \/ B}
      as non empty set;
      now
        let a be object;
        assume a in A;
        then ex t st ( a = t)&( not x.t in C);
        hence a in QC-symbols(Al);
      end;
      then reconsider A = {t : not x.t in still_not-bound_in {s} \/ B}
      as non empty Subset of QC-symbols(Al) by TARSKI:def 3;
      set u = Al-one_in A;
      u = the Element of A by QC_LANG1:def 41;
      then u in A;
      then
A91:  ex t st ( t = u)&( not x.t in C);
      then
A92:  not x.u in still_not-bound_in {s} by XBOOLE_0:def 3;
      still_not-bound_in (F.(k+1)) \/ still_not-bound_in r c= B
      by A84,A87,XBOOLE_1:9;
      then still_not-bound_in (F.(k+1)) \/ still_not-bound_in {r} c= B by Th26;
      then
A93:  still_not-bound_in (F.(k+1) \/ {r}) c= B by Th27;
      then still_not-bound_in (F.(k+1+1)) c= B by A54,A86;
      then not x.u in still_not-bound_in (F.(k+1+1)) by A91,XBOOLE_0:def 3;
      then not x.u in still_not-bound_in (F.(k+1+1)) \/
      still_not-bound_in {s} by A92,XBOOLE_0:def 3;
      hence thesis by A54,A86,A93,Th27;
    end;
    for k holds P[k] from NAT_1:sch 2(A76,A83);
    hence thesis;
  end;
  defpred P[Nat] means F.$1 is Consistent;
  now
    let a be object;
    assume a in {(h.i)`1 : i in 0};
    then ex j st ( a = (h.j)`1)&( j in 0);
    hence contradiction;
  end;
  then {(h.i)`1 : i in 0} = {} by XBOOLE_0:def 1;
  then
A94: F.0 = CX \/ {} by A22;
  then
A95: P[0];
A96: for k st P[k] holds P[k+1]
  proof
    let k such that
A97: P[k];
    ex c,d being object st
( c in CQC-WFF(Al))&( d in bool bound_QC-variables(Al))&(
    h.k = [c,d]) by ZFMISC_1:def 2;
    then reconsider r = (h.k)`1 as Element of CQC-WFF(Al);
    now
      assume F.(k+1) is Inconsistent;
      then F.(k+1) |- 'not' VERUM(Al) by HENMODEL:6;
      then F.k \/ {r} |- 'not' VERUM(Al) by A54;
      then consider f1 being FinSequence of CQC-WFF(Al) such that
A98:  rng f1 c= F.k and
A99:  |- f1^<*r*>^<*'not' VERUM(Al)*> by HENMODEL:8;
A100:  |- f1^<*'not' (f.k)*>^<*'not' (f.k)*> by CALCUL_2:21;
A101:  now
        assume
A102:   k = 0;
        then
A103:   r = 'not' (f.0) 'or' (the_scope_of(f,0).(bound_in(f,0),
        x.(Al-one_in {t : not x.t in still_not-bound_in (CX \/ {f.0})})))
        by A6;
        reconsider s = the_scope_of(f,0).(bound_in(f,0),
        x.(Al-one_in {t : not x.t in still_not-bound_in (CX \/ {f.0})}))
        as Element of CQC-WFF(Al);
A104:   |- (f1^<*'not' (f.k)*>)^<*('not' (f.k)) 'or' s*> by A100,CALCUL_1:51;
        0+1 <= len (f1^<*r*>) by CALCUL_1:10;
        then |- Ant(f1^<*r*>)^<*'not' (f.k)*>^<*Suc(f1^<*r*>)*>^<*'not'
        VERUM(Al)*> by A99,Th25;
        then |- f1^<*'not' (f.k)*>^<*Suc(f1^<*r*>)*>^<*'not' VERUM(Al)*>
        by CALCUL_1:5;
        then |- (f1^<*'not' (f.k)*>)^<*r*>^<*'not' VERUM(Al)*> by CALCUL_1:5;
        then
A105:   |- f1^<*'not' (f.k)*>^<*'not' VERUM(Al)*>
        by A102,A103,A104,CALCUL_2:24;
        |- f1^<*s*>^<*s*> by CALCUL_2:21;
        then
A106:   |- f1^<*s*>^<*('not' (f.k)) 'or' s*> by CALCUL_1:52;
        0+1 <= len (f1^<*r*>) by CALCUL_1:10;
        then |- Ant(f1^<*r*>)^<*s*>^<*Suc(f1^<*r*>)*>^<*'not' VERUM(Al)*>
        by A99,Th25;
        then |- f1^<*s*>^<*Suc(f1^<*r*>)*>^<*'not' VERUM(Al)*> by CALCUL_1:5;
        then |- (f1^<*s*>)^<*r*>^<*'not' VERUM(Al)*> by CALCUL_1:5;
        then
A107:   |- f1^<*s*>^<*'not' VERUM(Al)*> by A102,A103,A106,CALCUL_2:24;
        reconsider r1 = f.0 as Element of CQC-WFF(Al);
        set C = still_not-bound_in (CX \/ {r1});
        still_not-bound_in r1 is finite by CQC_SIM1:19;
        then still_not-bound_in {r1} is finite by Th26;
        then still_not-bound_in {r1} \/ still_not-bound_in CX is finite by A2;
        then C is finite by Th27;
        then consider x such that
A108:   not x in C by Th28;
        consider u such that
A109:   x.u = x by QC_LANG3:30;
        u in {t : not x.t in C} by A108,A109;
        then reconsider A = {t : not x.t in C} as non empty set;
        now
          let a be object;
          assume a in A;
          then ex t st ( a = t)&( not x.t in C);
          hence a in QC-symbols(Al);
        end;
        then reconsider A = {t : not x.t in C} as
             non empty Subset of QC-symbols(Al)
        by TARSKI:def 3;
        set u = Al-one_in A;
        u = the Element of A by QC_LANG1:def 41;
        then u in A;
        then consider t such that
A110:   t = u and
A111:   not x.t in C;
A112:   not x.t in still_not-bound_in CX \/ still_not-bound_in {r1}
        by A111,Th27;
        then
A113:   not x.t in still_not-bound_in {r1} by XBOOLE_0:def 3;
A114:   F.0 = CX \/ {(h.n)`1 : n in 0} by A22;
        now
          let b be object;
          assume b in {(h.n)`1 : n in 0};
          then ex n st ( b = (h.n)`1)&( n in 0);
          hence contradiction;
        end;
        then {(h.n)`1 : n in 0} = {} by XBOOLE_0:def 1;
        then still_not-bound_in rng f1 c=
        still_not-bound_in CX by A98,A102,A114,Th29;
        then not x.t in still_not-bound_in rng f1 by A112,XBOOLE_0:def 3;
        then
A115:   not x.u in still_not-bound_in f1 by A110,Th30;
        reconsider r2 = the_scope_of(f,0) as Element of CQC-WFF(Al);
        reconsider y2 = bound_in(f,0) as bound_QC-variable of Al;
        r1 in ExCl(Al) by A3,A4,FUNCT_1:3;
        then consider y1,s1 such that
A116:   r1 = Ex(y1,s1) by Def3;
A117:   s1 = Ex-the_scope_of r1 by A116,Th22;
A118:   r2 = Ex-the_scope_of r1 by Def7;
A119:   y1 = Ex-bound_in r1 by A116,Th22;
A120:   y2 = Ex-bound_in r1 by Def6;
        not x.u in still_not-bound_in r1 by A110,A113,Th26;
        then not x.u in still_not-bound_in <*r1*> by CALCUL_1:60;
        then not x.u in still_not-bound_in f1 \/ still_not-bound_in <*r1*>
        by A115,XBOOLE_0:def 3;
        then
A121:   not x.u in still_not-bound_in (f1^<*r1*>) by CALCUL_1:59;
        still_not-bound_in VERUM(Al) = {} by QC_LANG3:3;
        then not x.u in still_not-bound_in 'not' VERUM(Al) by QC_LANG3:7;
        then not x.u in still_not-bound_in <*'not' VERUM(Al)*>
        by CALCUL_1:60;
        then not x.u in still_not-bound_in (f1^<*r1*>) \/
        still_not-bound_in <*'not' VERUM(Al)*> by A121,XBOOLE_0:def 3;
        then not x.u in still_not-bound_in (f1^<*r1*>^<*'not' VERUM(Al)*>)
        by CALCUL_1:59;
        then |- f1^<*r1*>^<*'not' VERUM(Al)*> by A107,A116,A117,A118,A119,A120,
CALCUL_1:61;
        then |- f1^<*'not' VERUM(Al)*> by A102,A105,CALCUL_2:26;
        then F.k |- 'not' VERUM(Al) by A98,HENMODEL:def 1;
        hence contradiction by A94,A102,Th24;
      end;
      now
        assume k <> 0;
        then consider k1 being Nat such that
A122:   k = k1+1 by NAT_1:6;
        reconsider k1 as Nat;
A123:   ex K,L st K = (h.k1)`2 & L = K \/ still_not-bound_in {f.(k1+1)} &
        h.(k1+1) = [('not' (f.(k1+1))) 'or' (the_scope_of(f,(k1+1)).
        (bound_in(f,k1+1),x.(Al-one_in {t : not x.t in L}))),
        K \/ still_not-bound_in
        ('not' (f.(k1+1))) 'or' (the_scope_of(f,k1+1).(bound_in(f,k1+1),
        x.(Al-one_in {u : not x.u in L})))] by A6;
        set K = (h.k1)`2;
        set r1 = f.(k1+1);
        set L = K \/ still_not-bound_in {r1};
        set p1 = 'not' r1 'or' (the_scope_of(f,(k1+1)).
        (bound_in(f,k1+1),x.(Al-one_in {t : not x.t in L})));
A124:   r = p1 by A122,A123;
        reconsider s = (the_scope_of(f,(k1+1)).
        (bound_in(f,k1+1),x.(Al-one_in {t : not x.t in L})))
        as Element of CQC-WFF(Al);
A125:   |- (f1^<*'not' r1*>)^<*p1*> by A100,A122,CALCUL_1:51;
        0+1 <= len (f1^<*r*>) by CALCUL_1:10;
        then |- Ant(f1^<*r*>)^<*'not' r1*>^<*Suc(f1^<*r*>)*>^
        <*'not' VERUM(Al)*> by A99,Th25;
        then |- f1^<*'not' r1*>^<*Suc(f1^<*r*>)*>^<*'not' VERUM(Al)*>
        by CALCUL_1:5;
        then |- (f1^<*'not' r1*>)^<*r*>^<*'not' VERUM(Al)*> by CALCUL_1:5;
        then
A126:   |- f1^<*'not' r1*>^<*'not' VERUM(Al)*> by A124,A125,CALCUL_2:24;
        |- f1^<*s*>^<*s*> by CALCUL_2:21;
        then
A127:   |- f1^<*s*>^<*p1*> by CALCUL_1:52;
        0+1 <= len (f1^<*r*>) by CALCUL_1:10;
        then |- Ant(f1^<*r*>)^<*s*>^<*Suc(f1^<*r*>)*>^<*'not' VERUM(Al)*>
        by A99,Th25;
        then |- f1^<*s*>^<*Suc(f1^<*r*>)*>^<*'not' VERUM(Al)*> by CALCUL_1:5;
        then |- (f1^<*s*>)^<*p1*>^<*'not' VERUM(Al)*> by A124,CALCUL_1:5;
        then
A128:   |- f1^<*s*>^<*'not' VERUM(Al)*> by A127,CALCUL_2:24;
        set y = x.(Al-one_in {t : not x.t in L});
        set u = Al-one_in {t : not x.t in L};
        reconsider r2 = the_scope_of(f,k1+1) as Element of CQC-WFF(Al);
        reconsider y2 = bound_in(f,k1+1) as bound_QC-variable of Al;
        reconsider r1 as Element of CQC-WFF(Al);
        r1 in ExCl(Al) by A3,A4,FUNCT_1:3;
        then consider y1,s1 such that
A129:   r1 = Ex(y1,s1) by Def3;
A130:   s1 = Ex-the_scope_of r1 by A129,Th22;
A131:   r2 = Ex-the_scope_of r1 by Def7;
A132:   y1 = Ex-bound_in r1 by A129,Th22;
A133:   y2 = Ex-bound_in r1 by Def6;
        reconsider Z = F.k as Subset of CQC-WFF(Al);
        not y in still_not-bound_in (Z \/ {r1}) by A75,A122;
        then
A134:   not y in still_not-bound_in Z \/ still_not-bound_in {r1} by Th27;
        then
A135:   not y in still_not-bound_in { r1} by XBOOLE_0:def 3;
        still_not-bound_in rng f1 c= still_not-bound_in Z by A98,Th29;
        then not y in still_not-bound_in rng f1 by A134,XBOOLE_0:def 3;
        then
A136:   not y in still_not-bound_in f1 by Th30;
        not y in still_not-bound_in r1 by A135,Th26;
        then not y in still_not-bound_in <*r1*> by CALCUL_1:60;
        then not y in still_not-bound_in f1 \/
        still_not-bound_in <*r1*> by A136,XBOOLE_0:def 3;
        then
A137:   not y in still_not-bound_in (f1^<*r1*>) by CALCUL_1:59;
        still_not-bound_in VERUM(Al) = {} by QC_LANG3:3;
        then not x.u in still_not-bound_in 'not' VERUM(Al) by QC_LANG3:7;
        then not x.u in still_not-bound_in <*'not' VERUM(Al)*>
        by CALCUL_1:60;
        then not x.u in still_not-bound_in (f1^<*r1*>) \/
        still_not-bound_in <*'not' VERUM(Al)*> by A137,XBOOLE_0:def 3;
        then not x.u in still_not-bound_in (f1^<*r1*>^<*'not' VERUM(Al)*>)
        by CALCUL_1:59;
        then |- f1^<*r1*>^<*'not' VERUM(Al)*> by A128,A129,A130,A131,A132,A133,
CALCUL_1:61;
        then |- f1^<*'not' VERUM(Al)*> by A126,CALCUL_2:26;
        then F.k |- 'not' VERUM(Al) by A98,HENMODEL:def 1;
        hence contradiction by A97,Th24;
      end;
      hence contradiction by A101;
    end;
    hence thesis;
  end;
  for n holds P[n] from NAT_1:sch 2(A95,A96);
  then for n,m st m in dom F & n in dom F & n < m holds F.n is Consistent &
  F.n c= F.m by A41;
  then reconsider CY as Consistent Subset of CQC-WFF(Al) by A40,HENMODEL:11;
  take CY;
  thus thesis by A9,XBOOLE_1:7;
end;
