
theorem
  for n being Ordinal, L being right_zeroed add-associative
  right_complementable well-unital distributive non trivial
  doubleLoopStr, f,g being Polynomial of n,L, P being non empty Subset of
  Polynom-Ring(n,L), A,B being LeftLinearCombination of P st A
  is_MonomialRepresentation_of f & B is_MonomialRepresentation_of g holds (A^B)
  is_MonomialRepresentation_of f+g
proof
  let n be Ordinal, L be right_zeroed add-associative right_complementable
  well-unital distributive non trivial doubleLoopStr, f,g be
  Polynomial of n,L, P be non empty Subset of Polynom-Ring(n,L), A,B be
  LeftLinearCombination of P;
  assume that
A1: A is_MonomialRepresentation_of f and
A2: B is_MonomialRepresentation_of g;
A3: now
    let i be Element of NAT;
    assume
A4: i in dom(A^B);
    now
      per cases by A4,FINSEQ_1:25;
      case
A5:     i in dom A;
        dom A c= dom(A^B) by FINSEQ_1:26;
        then (A^B)/.i = (A^B).i by A5,PARTFUN1:def 6
          .= A.i by A5,FINSEQ_1:def 7
          .= A/.i by A5,PARTFUN1:def 6;
        hence
        ex m being Monomial of n,L, p being Polynomial of n,L st p in P &
        (A^B)/.i = m *' p by A1,A5;
      end;
      case
        ex k being Nat st k in dom B & i = len A + k;
        then consider k being Nat such that
A6:     k in dom B and
A7:     i = len A + k;
        i in dom(A^B) by A6,A7,FINSEQ_1:28;
        then (A^B)/.i = (A^B).i by PARTFUN1:def 6
          .= B.k by A6,A7,FINSEQ_1:def 7
          .= B/.k by A6,PARTFUN1:def 6;
        hence
        ex m being Monomial of n,L, p being Polynomial of n,L st p in P &
        (A^B)/.i = m *' p by A2,A6;
      end;
    end;
    hence
    ex m being Monomial of n,L, p being Polynomial of n,L st p in P & (A^
    B)/.i = m *' p;
  end;
  reconsider f9 = f, g9 = g as Element of Polynom-Ring(n,L) by POLYNOM1:def 11;
  reconsider f9,g9 as Element of Polynom-Ring(n,L);
  Sum(A^B) = Sum A + Sum B by RLVECT_1:41
    .= f9 + Sum B by A1
    .= f9 + g9 by A2
    .= f + g by POLYNOM1:def 11;
  hence thesis by A3;
end;
