reserve R for commutative Ring;
reserve A for non degenerated commutative Ring;
reserve I,J,q for Ideal of A;
reserve p for prime Ideal of A;
reserve M,M1,M2 for Ideal of A/q;

theorem Th35:
    I is primary iff
    A/I is non degenerated &
    (for x be Element of A/I st x is zero_divisible holds x is nilpotent)
    proof
A1:   I is primary implies
      A/I is non degenerated &
      (for x be Element of A/I st x is zero_divisible holds x is nilpotent)
      proof
        assume I is primary; then
        I <> [#]A & for x1,y1 be Element of A st x1*y1 in I & not x1 in I holds
        y1 in sqrt I by Th33;
        hence thesis by Th34;
      end;
      A/I is non degenerated &
      (for x be Element of A/I st x is zero_divisible holds x is nilpotent)
      implies I is primary
      proof
        assume A/I is non degenerated &
        (for x be Element of A/I st x is zero_divisible holds x is nilpotent);
          then
        (I <> [#]A &
        for x,y be Element of A st x*y in I & not x in I holds y in sqrt I)
        by Th34;
        hence thesis by Th33;
      end;
      hence thesis by A1;
    end;
