reserve a,b,c for Integer;
reserve i,j,k,l for Nat;
reserve n for Nat;
reserve a,b,c,d,a1,b1,a2,b2,k,l for Integer;
reserve p,p1,q,l for Nat;

theorem
  for n being Nat holds
  n >= 2 implies ex p being Element of NAT st p is prime & p divides n
proof
  defpred P[Nat] means ex p st p is prime & p divides $1;
A1: for k being Nat st k>=2 holds (for n being Nat st n>=2 holds n<k implies
  P[n]) implies P[k]
  proof
    let k be Nat;
    assume
A2: k>=2;
    assume
A3: for n being Nat st n>=2 holds n<k implies ex p st p is prime & p divides n;
A4: k+1-1>1+1-1 by A2,NAT_1:13;
    not k is prime implies ex p being Element of NAT st p is prime & p
    divides k
    proof
      assume not k is prime;
      then consider m being Nat such that
A5:   m divides k and
A6:   m<>1 and
A7:   m<>k by A4;
      m<>0 by A5,A7;
      then m>0;
      then m>=0+1 by NAT_1:13;
      then m>1 by A6,XXREAL_0:1;
      then
A8:   m>=1+1 by NAT_1:13;
      m<=k by A2,A5,Th27;
      then m<k by A7,XXREAL_0:1;
      then consider p1 such that
A9:   p1 is prime & p1 divides m by A3,A8;
      reconsider p1 as Element of NAT by ORDINAL1:def 12;
      take p1;
      thus thesis by A5,A9,Lm2;
    end;
    hence thesis;
  end;
A10: for k being Nat st k>=2 holds P[k] from NAT_1:sch 9(A1);
  let n be Nat;
  assume n >= 2;
  then consider p such that
A11: p is prime & p divides n by A10;
  reconsider p as Element of NAT by ORDINAL1:def 12;
  take p;
  thus thesis by A11;
end;
