reserve p,p1,p2,p3,q,q1,q2 for Point of TOP-REAL 2,
  i for Nat,
  lambda for Real;

theorem Th31:
  for a,b,c,d being Real st a <= b & c <= d holds
  LSeg(|[a,c]|,|[a,d]|) /\ LSeg(|[a,c]|,|[b,c]|) = {|[a,c]|}
proof
  let a,b,c,d be Real;
  assume that
A1: a <= b and
A2: c <= d;
  for ax being object
  holds ax in LSeg(|[a,c]|,|[a,d]|) /\ LSeg(|[a,c]|,|[b,c]|) iff ax = |[a,c]|
  proof
    let ax be object;
    thus ax in LSeg(|[a,c]|,|[a,d]|) /\ LSeg(|[a,c]|,|[b,c]|)
    implies ax = |[a,c]|
    proof
      assume
A3:   ax in LSeg(|[a,c]|,|[a,d]|) /\ LSeg(|[a,c]|,|[b,c]|);
      then
A4:   ax in LSeg(|[a,c]|,|[a,d]|) by XBOOLE_0:def 4;
      ax in LSeg(|[a,c]|,|[b,c]|) by A3,XBOOLE_0:def 4;
      then ax in { p2 : p2`1 <= b & p2`1 >= a & p2`2 = c } by A1,Th30;
      then
A5:   ex p2 st p2 = ax & p2`1 <= b & p2`1 >= a & p2`2 = c;
      ax in { p2 : p2`1 = a & p2`2 <= d & p2`2 >= c } by A2,A4,Th30;
      then ex p st p = ax & p`1 = a & p`2 <= d & p`2 >= c;
      hence thesis by A5,EUCLID:53;
    end;
    assume
A6: ax = |[a,c]|;
    then
A7: ax in LSeg(|[a,c]|,|[a,d]|) by RLTOPSP1:68;
    ax in LSeg(|[a,c]|,|[b,c]|) by A6,RLTOPSP1:68;
    hence thesis by A7,XBOOLE_0:def 4;
  end;
  hence thesis by TARSKI:def 1;
end;
