reserve i, i1, i2, j, j1, j2, k, m, n, t for Nat,
  D for non empty Subset of TOP-REAL 2,
  E for compact non vertical non horizontal Subset of TOP-REAL 2,
  C for compact connected non vertical non horizontal Subset of TOP-REAL 2,
  G for Go-board,
  p, q, x for Point of TOP-REAL 2,
  r, s for Real;

theorem Th31:
  m <= n & 1 < i & i < len Gauge(D,m) implies 1 < 2|^(n-'m)*(i-2)+
  2 & 2|^(n-'m)*(i-2)+2 < len Gauge(D,n)
proof
  assume that
A1: m <= n and
A2: 1 < i and
A3: i < len Gauge(D,m);
  1+1 <= i by A2,NAT_1:13;
  then reconsider i2 = i-2 as Element of NAT by INT_1:5;
  0 < 2|^(n-'m)*(i2)+1;
  then 0+1 < 2|^(n-'m)*(i-2)+1+1 by XREAL_1:6;
  hence 1 < 2|^(n-'m)*(i-2)+2;
  len Gauge(D,m) = 2|^m + (2+1) by JORDAN8:def 1
    .= 2|^m + 2+1;
  then i <= 2|^m + 2 by A3,NAT_1:13;
  then i2 <= 2|^m by XREAL_1:20;
  then 2|^(n-'m)*(i2) <= 2|^(n-'m)*2|^m by XREAL_1:64;
  then 2|^(n-'m)*(i2) <= 2|^(n-'m+m) by NEWTON:8;
  then 2|^(n-'m)*(i2) <= 2|^n by A1,XREAL_1:235;
  then 2|^(n-'m)*(i2) < 2|^n + 1 by NAT_1:13;
  then 2|^(n-'m)*(i-2)+2 < 2|^n + 1+2 by XREAL_1:6;
  then 2|^(n-'m)*(i-2)+2 < 2|^n + (1+2);
  hence thesis by JORDAN8:def 1;
end;
