reserve m,k,j,j1,i,i1,i2,n for Nat,
  r,s for Real,
  C for compact non vertical non horizontal Subset of TOP-REAL 2,
  G for Go-board,
  p for Point of TOP-REAL 2;

theorem Th31:
  for f being non empty FinSequence of TOP-REAL 2, G being
Go-board st f is_sequence_on G & (ex i st [i,1] in Indices G & G*(i,1) in rng f
  ) & (ex i st [i,width G] in Indices G & G*(i,width G) in rng f) holds proj2.:
  rng f = proj2.:Values G
proof
  let f be non empty FinSequence of TOP-REAL 2, G be Go-board such that
A1: f is_sequence_on G;
  given i1 being Nat such that
A2: [i1,1] in Indices G and
A3: G*(i1,1) in rng f;
  consider k1 being object such that
A4: k1 in dom f and
A5: G*(i1,1) = f.k1 by A3,FUNCT_1:def 3;
  reconsider k1 as Nat by A4;
A6: 1 <= k1 by A4,FINSEQ_3:25;
  given i2 being Nat such that
A7: [i2,width G] in Indices G and
A8: G*(i2,width G) in rng f;
  consider k2 being object such that
A9: k2 in dom f and
A10: G*(i2, width G) = f.k2 by A8,FUNCT_1:def 3;
  reconsider k2 as Nat by A9;
A11: k2 <= len f by A9,FINSEQ_3:25;
A12: k1 <= len f by A4,FINSEQ_3:25;
  set g = mid(f,k1,k2);
A13: g is_sequence_on G by A1,Th27;
A14: 1 <= k2 by A9,FINSEQ_3:25;
A15: now
    per cases;
    suppose
      k1 <= k2;
      then len g = k2-'k1+1 by A6,A11,FINSEQ_6:186;
      hence len g >= 0 qua Nat+1 by XREAL_1:6;
    end;
    suppose
      k1 > k2;
      then len g=k1-'k2+1 by A12,A14,FINSEQ_6:187;
      hence len g >= 0 qua Nat+1 by XREAL_1:6;
    end;
  end;
A16: Values G = { G*(i,j) where i,j is Nat: [i,j] in Indices G }
     by MATRIX_0:39;
A17: proj2.:Values G c= proj2.:rng g
  proof
    assume not thesis;
    then consider x being Element of REAL such that
A18: x in proj2.:Values G and
A19: not x in proj2.:rng g;
    consider p being Element of TOP-REAL 2 such that
A20: p in Values G and
A21: x = proj2.p by A18,FUNCT_2:65;
    consider i0,j0 being Nat such that
A22: p = G*(i0,j0) and
A23: [i0,j0] in Indices G by A16,A20;
A24: j0 <= width G by A23,MATRIX_0:32;
    defpred P[Nat] means 1 <= $1 & $1 <= len g implies for i,j st [i,j] in
    Indices G & G*(i,j) = g.$1 holds j < j0;
A25: 1 <= j0 by A23,MATRIX_0:32;
A26: 1 <= i0 & i0 <= len G by A23,MATRIX_0:32;
A27: for n st P[n] holds P[n+1]
    proof
      let n such that
A28:  1 <= n & n <= len g implies for i,j st [i,j] in Indices G & G*(
      i,j) = g.n holds j < j0 and
A29:  1 <= n+1 and
A30:  n+1 <= len g;
      let i,j such that
A31:  [i,j] in Indices G and
A32:  G*(i,j) = g.(n+1);
A33:  now
A34:    n+1 in dom g by A29,A30,FINSEQ_3:25;
        then
A35:    G*(i,j) = g/.(n+1) by A32,PARTFUN1:def 6;
        then
A36:    dom proj2 = the carrier of TOP-REAL 2 & g/.(n+1) in rng g by A32,A34,
FUNCT_1:3,FUNCT_2:def 1;
A37:    1 <= i & i <= len G by A31,MATRIX_0:32;
        assume
A38:    j = j0;
        x = p`2 by A21,PSCOMP_1:def 6
          .= G*(1,j0)`2 by A22,A26,A25,A24,GOBOARD5:1
          .= G*(i,j)`2 by A25,A24,A38,A37,GOBOARD5:1
          .= proj2.(g/.(n+1)) by A35,PSCOMP_1:def 6;
        hence contradiction by A19,A36,FUNCT_1:def 6;
      end;
      per cases;
      suppose
        n = 0;
        then G*(i,j) = G*(i1,1) by A5,A6,A12,A14,A11,A32,FINSEQ_6:118;
        then j = 1 by A2,A31,Th26;
        hence thesis by A25,A33,XXREAL_0:1;
      end;
      suppose
A39:    n <> 0;
        then
A40:    1 <= n by NAT_1:14;
A41:    n <= n + 1 by NAT_1:11;
        then n <= len g by A30,XXREAL_0:2;
        then
A42:    n in dom g by A40,FINSEQ_3:25;
        then consider i1,j1 being Nat such that
A43:    [i1,j1] in Indices G & g/.n = G*(i1,j1) by A13,GOBOARD1:def 9;
A44:    n+1 in dom g by A29,A30,FINSEQ_3:25;
        then g/.(n+1) = G*(i,j) by A32,PARTFUN1:def 6;
        then |.i1-i.|+|.j1-j.| = 1 by A13,A31,A42,A43,A44,GOBOARD1:def 9;
        then
A45:    |.i1-i.|=1 & j1=j or |.j1-j.|=1 & i1=i by SEQM_3:42;
        now
          g.n = g/.n by A42,PARTFUN1:def 6;
          then
A46:      j1 < j0 by A28,A30,A39,A41,A43,NAT_1:14,XXREAL_0:2;
          per cases by A45,SEQM_3:41;
          suppose
            j1 = j or j < j1;
            hence thesis by A46,XXREAL_0:2;
          end;
          suppose
            j = j1 + 1;
            then j <= j0 by A46,NAT_1:13;
            hence thesis by A33,XXREAL_0:1;
          end;
        end;
        hence thesis;
      end;
    end;
A47: G*(i2,width G) = g.len g by A6,A12,A10,A14,A11,FINSEQ_6:189;
A48: P[0];
    for n holds P[n] from NAT_1:sch 2(A48,A27);
    then width G < j0 by A7,A15,A47;
    hence contradiction by A23,MATRIX_0:32;
  end;
  thus proj2.:rng f c= proj2.:Values G by A1,GOBRD13:8,RELAT_1:123;
  proj2.:rng g c= proj2.:rng f by FINSEQ_6:119,RELAT_1:123;
  hence thesis by A17;
end;
