reserve n for Nat;

theorem
  for f be FinSequence of TOP-REAL 2 st f is special weakly-one-to-one
  for p,q be Point of TOP-REAL 2 st p in L~f & q in L~f holds B_Cut(f,p,q) is
  special
proof
  let f be FinSequence of TOP-REAL 2;
  assume
A1: f is special weakly-one-to-one;
  let p,q be Point of TOP-REAL 2;
  assume that
A2: p in L~f and
A3: q in L~f;
A4: Index(p,f) < len f by A2,JORDAN3:8;
A5: 1 <= Index(p,f) by A2,JORDAN3:8;
  then
A6: Index(p,f) in dom f by A4,FINSEQ_3:25;
  per cases;
  suppose
A7: p <> q;
    now
      per cases;
      suppose
A8:     p in L~f & q in L~f & Index(p,f) < Index(q,f);
        then
A9:     q in L~L_Cut(f,p) by JORDAN3:29;
        L_Cut(f,p) is special by A1,A2,Th29;
        then R_Cut(L_Cut(f,p),q) is special by A9,Th30;
        hence thesis by A8,JORDAN3:def 7;
      end;
      suppose
A10:    Index(p,f)=Index(q,f) & LE p,q,f/.(Index(p,f)),f/.(Index(p,f) +1);
A11:    L_Cut(f,p) is special by A1,A2,Th29;
        q in L~L_Cut(f,p) by A2,A3,A7,A10,JORDAN3:31;
        then R_Cut(L_Cut(f,p),q) is special by A11,Th30;
        hence thesis by A10,JORDAN3:def 7;
      end;
      suppose
A12:    not (p in L~f & q in L~f & Index(p,f) < Index(q,f) or Index(p
        ,f)=Index(q,f) & LE p,q,f/.(Index(p,f)),f/.(Index(p,f)+1));
A13:    now
          per cases by A2,A3,A12,XXREAL_0:1;
          suppose
            Index(q,f) < Index(p,f);
            hence p in L~L_Cut(f,q) by A2,A3,JORDAN3:29;
          end;
          suppose
A14:        Index(q,f) = Index(p,f);
A15:        Index(p,f)+1 >= 1 by NAT_1:11;
            Index(p,f)+1 <= len f by A4,NAT_1:13;
            then
A16:        Index(p,f)+1 in dom f by A15,FINSEQ_3:25;
            set Ls = LSeg(f/.(Index(p,f)),f/.(Index(p,f)+1));
A17:        q in Ls by A3,A14,JORDAN5B:29;
A18:        p in Ls by A2,JORDAN5B:29;
            f.Index(p,f) <> f.(Index(p,f)+1) by A1,A5,A4;
            then f.Index(p,f) <> f/.(Index(p,f)+1) by A16,PARTFUN1:def 6;
            then
A19:        f/.Index(p,f) <> f/.(Index(p,f)+1) by A6,PARTFUN1:def 6;
            then
A20:        Ls is_an_arc_of f/.(Index(p,f)),f/.(Index(p,f)+1) by TOPREAL1:9;
            not LE p,q,Ls,f/.(Index(p,f)),f/.(Index(p,f)+1) by A12,A14,A19,
JORDAN5C:17;
            then LE q,p,Ls,f/.(Index(p,f)),f/.(Index(p,f)+1) by A7,A20,A18,A17,
JORDAN5C:14;
            hence p in L~L_Cut(f,q) by A2,A3,A7,A14,A19,JORDAN3:31,JORDAN5C:17;
          end;
        end;
A21:    B_Cut(f,p,q) = Rev (R_Cut(L_Cut(f,q),p)) by A12,JORDAN3:def 7;
        L_Cut(f,q) is special by A1,A3,Th29;
        then R_Cut(L_Cut(f,q),p) is special by A13,Th30;
        hence thesis by A21,SPPOL_2:40;
      end;
    end;
    hence thesis;
  end;
  suppose
    p = q;
    then B_Cut(f,p,q) = <*p*> by A1,A2,Th15;
    hence thesis;
  end;
end;
