reserve i,j,k,n for Nat,
  D for non empty set,
  f, g for FinSequence of D;
reserve G for Go-board,
  f, g for FinSequence of TOP-REAL 2,
  p for Point of TOP-REAL 2,
  r, s for Real,
  x for set;
reserve C for compact non vertical non horizontal non empty Subset of TOP-REAL
  2,
  l, m, i1, i2, j1, j2 for Nat;

theorem Th31:
  C is connected implies
 for n,k being Nat st 1 <= k & k+1 <= len Cage(C,n)
holds left_cell
(Cage(C,n),k,Gauge(C,n)) misses C & right_cell(Cage(C,n),k,Gauge(C,n)) meets C
proof
  assume
A1: C is connected;
  let n be Nat;
  set G = Gauge(C,n), f = Cage(C,n);
  set W = W-bound C, E = E-bound C, S = S-bound C, N = N-bound C;
A2: f is_sequence_on G by A1,Def1;
  defpred P[Nat] means
   for m being Nat  st 1 <= m & m+1 <= len(f|$1) holds
  left_cell(f|$1,m,G) misses C & right_cell(f|$1,m,G) meets C;
A3: len G = width G by JORDAN8:def 1;
A4: len G = 2|^n+3 by JORDAN8:def 1;
A5: for k being Nat st P[k] holds P[k+1]
  proof
    let k be Nat such that
A6: for m being Nat st 1 <= m & m+1 <= len(f|k) holds left_cell(f|k,m,G)
    misses C & right_cell(f|k,m,G) meets C;
    per cases;
    suppose
      k >= len f;
      then f|k = f & f|(k+1) = f by FINSEQ_1:58,NAT_1:12;
      hence thesis by A6;
    end;
    suppose
A7:   k < len f;
      then
A8:   len(f|k) = k by FINSEQ_1:59;
A9:   1 <= len G by A4,NAT_1:12;
A10:  f|k is_sequence_on G by A2,GOBOARD1:22;
A11:  f|(k+1) is_sequence_on G by A2,GOBOARD1:22;
      consider i being Nat such that
A12:  1 <= i and
A13:  i+1 <= len G and
A14:  f/.1 = G*(i,width G) & f/.2 = G*(i+1,width G) and
A15:  N-min C in cell(G,i,width G-'1) and
      N-min C <> G*(i,width G-'1) by A1,Def1;
      let m be Nat such that
A16:  1 <= m and
A17:  m+1 <= len(f|(k+1));
A18:  k+1 <= len f by A7,NAT_1:13;
      then
A19:  len(f|(k+1)) = k+1 by FINSEQ_1:59;
A20:  2|^n >= n+1 by NEWTON:85;
      now
        per cases by NAT_1:25;
        suppose
A21:      k = 0;
          1 <= m+1 by NAT_1:12;
          then m+1 = 0+1 by A17,A21,XXREAL_0:1;
          hence thesis by A16;
        end;
        suppose
A22:      k = 1;
          1+1 <= m+1 by A16,XREAL_1:6;
          then
A23:      m+1 = 1+1 by A19,A17,A22,XXREAL_0:1;
          f|(k+1) = <*G*(i,width G),G*(i+1,width G)*> by A18,A14,A22,
FINSEQ_5:81;
          then
A24:      (f|(k+1))/.1 = G*(i,width G) & (f|(k+1))/.2 = G*(i+1, width G)
          by FINSEQ_4:17;
          1 <= i+1 by A12,NAT_1:13;
          then
A25:      [i+1,len G] in Indices G by A3,A13,A9,MATRIX_0:30;
A26:      i < len G by A13,NAT_1:13;
          then
A27:      [i,len G] in Indices G by A3,A12,A9,MATRIX_0:30;
A28:      i < i+1 & i+1 < (i+1)+1 by NAT_1:13;
          then
A29:      left_cell(f|(k+1),m,G) = cell(G,i,len G) by A3,A11,A17,A24,A27,A25
,A23,GOBRD13:def 3;
          now
            N > S by JORDAN8:9;
            then N-S > S-S by XREAL_1:9;
            then (N-S)/(2|^n) > 0 by A20,XREAL_1:139;
            then
A30:        N+0 < N+(N-S)/(2|^n) by XREAL_1:6;
            assume left_cell(f|(k+1),m,G) meets C;
            then consider p being object such that
A31:        p in cell(G,i,len G) and
A32:        p in C by A29,XBOOLE_0:3;
            reconsider p as Element of TOP-REAL 2 by A31;
A33:        p`2 <= N by A32,PSCOMP_1:24;
            [1,len G] in Indices G by A3,A9,MATRIX_0:30;
            then G*(1,len G) = |[W+((E-W)/(2|^n))*(1-2),S+((N-S)/(2 |^n))*((
            len G)- 2)]| by JORDAN8:def 1;
            then
A34:        G*(1,len G)`2 = S+((N-S)/(2|^n))*((len G)-2) by EUCLID:52;
            cell(G,i,len G) = { |[r,s]|: G*(i,1)`1 <= r & r <= G*(i+1,1)
            `1 & G*(1,len G)`2 <= s } by A3,A12,A26,GOBRD11:31;
            then consider r,s such that
A35:        p = |[r,s]| and
            G*(i,1)`1 <= r and
            r <= G*(i+1,1)`1 and
A36:        G*(1,len G)`2 <= s by A31;
            ((N-S)/(2|^n))*((len G)-2) = ((N-S)/(2|^n))*(2|^n)+((N-S)/(2
            |^n))*1 by A4
              .= (N-S)+(N-S)/(2|^n) by A20,XCMPLX_1:87;
            then N < s by A36,A34,A30,XXREAL_0:2;
            hence contradiction by A35,A33,EUCLID:52;
          end;
          hence left_cell(f|(k+1),m,G) misses C;
          N-min C in C & N-min C in right_cell(f|(k+1),m,G) by A3,A11,A15,A17
,A24,A27,A25,A23,A28,GOBRD13:def 2,SPRECT_1:11;
          hence right_cell(f|(k+1),m,G) meets C by XBOOLE_0:3;
        end;
        suppose
A37:      k > 1;
          then
A38:      (len(f|k)) -'1 +1 = len(f|k) by A8,XREAL_1:235;
A39:      1 <= (len(f|k))-'1 by A8,A37,NAT_D:49;
          now
            per cases;
            suppose
A40:          m+1 = len(f|(k+1));
A41:          len(f|k) <= len f by FINSEQ_5:16;
              now
                left_cell(f|k,(len(f|k))-'1,G) misses C by A6,A39,A38;
                then
A42:            left_cell(f,(len(f|k))-'1,G) misses C by A2,A8,A39,A38,A41,
GOBRD13:31;
A43:            (len(f|k))-'1+(1+1) = (len(f|k))+1 by A38;
                right_cell(f|k,(len(f|k))-'1,G) meets C by A6,A39,A38;
                then
A44:            right_cell(f,(len(f|k))-'1,G) meets C by A2,A8,A39,A38,A41,
GOBRD13:31;
                consider i1,j1,i2,j2 being Nat such that
A45:            [i1,j1] in Indices G & f/.((len(f|k)) -'1) = G*(i1,j1 ) and
A46:            [i2,j2] in Indices G and
A47:            f/.len(f|k) = G*(i2,j2) and
                i1 = i2 & j1+1 = j2 or i1+1 = i2 & j1 = j2 or i1 = i2+1 &
                j1 = j2 or i1 = i2 & j1 = j2+1 by A2,A7,A8,A39,A38,JORDAN8:3;
                1 <= i2 by A46,MATRIX_0:32;
                then
A48:            (i2-'1)+1 = i2 by XREAL_1:235;
                1 <= j2 by A46,MATRIX_0:32;
                then
A49:            (j2-'1)+1 = j2 by XREAL_1:235;
                per cases;
                suppose
A50:              front_left_cell(f,(len(f|k))-'1,G) misses C &
                  front_right_cell(f,(len(f|k))-'1,G) misses C;
                  then
A51:              f turns_right (len(f|k))-'1,G by A1,A18,A8,A39,A43,Def1;
                  now
                    per cases by A38,A45,A46,A47,A51;
                    suppose that
A52:                  i1 = i2 & j1+1 = j2 and
A53:                  [i2+1,j2] in Indices G & f/.((len(f|k))+1) = G*
                      (i2+1,j2);
                      front_right_cell(f,(len(f|k))-'1,G) = cell(G,i1,j2)
                      by A2,A39,A38,A41,A45,A46,A47,A52,GOBRD13:35;
                      then
                      left_cell(f,m,G) misses C by A2,A18,A8,A19,A16,A40,A46
,A47,A50,A52,A53,GOBRD13:23;
                      hence left_cell(f|(k+1),m,G) misses C by A2,A18,A19,A16
,A40,GOBRD13:31;
                      j2-'1 = j1 & cell(G,i1,j1) meets C by A2,A39,A38,A41,A45
,A46,A47,A44,A52,GOBRD13:22,NAT_D:34;
                      then
                      right_cell(f,m,G) meets C by A2,A18,A8,A19,A16,A40,A46
,A47,A52,A53,GOBRD13:24;
                      hence right_cell(f|(k+1),m,G) meets C by A2,A18,A19,A16
,A40,GOBRD13:31;
                    end;
                    suppose that
A54:                  i1+1 = i2 & j1 = j2 and
A55:                  [i2,j2-'1] in Indices G & f/.((len(f|k))+1) = G
                      *(i2,j2-'1);
                      front_right_cell(f,(len(f|k))-'1,G) = cell(G,i2,j2
                      -'1) by A2,A39,A38,A41,A45,A46,A47,A54,GOBRD13:37;
                      then
                      left_cell(f,m,G) misses C by A2,A18,A8,A19,A16,A40,A46
,A47,A49,A50,A55,GOBRD13:27;
                      hence left_cell(f|(k+1),m,G) misses C by A2,A18,A19,A16
,A40,GOBRD13:31;
                      i2-'1 = i1 & cell(G,i1,j1-'1) meets C by A2,A39,A38,A41
,A45,A46,A47,A44,A54,GOBRD13:24,NAT_D:34;
                      then
                      right_cell(f,m,G) meets C by A2,A18,A8,A19,A16,A40,A46
,A47,A49,A54,A55,GOBRD13:28;
                      hence right_cell(f|(k+1),m,G) meets C by A2,A18,A19,A16
,A40,GOBRD13:31;
                    end;
                    suppose that
A56:                  i1 = i2+1 & j1 = j2 and
A57:                  [i2,j2+1] in Indices G & f/.((len(f|k))+1) = G*
                      (i2,j2+1);
                      front_right_cell(f,(len(f|k))-'1,G) = cell(G,i2-'1,
                      j2) by A2,A39,A38,A41,A45,A46,A47,A56,GOBRD13:39;
                      then
                      left_cell(f,m,G) misses C by A2,A18,A8,A19,A16,A40,A46
,A47,A50,A57,GOBRD13:21;
                      hence left_cell(f|(k+1),m,G) misses C by A2,A18,A19,A16
,A40,GOBRD13:31;
                      cell(G,i2,j2) meets C by A2,A39,A38,A41,A45,A46,A47,A44
,A56,GOBRD13:26;
                      then
                      right_cell(f,m,G) meets C by A2,A18,A8,A19,A16,A40,A46
,A47,A57,GOBRD13:22;
                      hence right_cell(f|(k+1),m,G) meets C by A2,A18,A19,A16
,A40,GOBRD13:31;
                    end;
                    suppose that
A58:                  i1 = i2 & j1 = j2+1 and
A59:                  [i2-'1,j2] in Indices G & f/.((len(f|k))+1) = G
                      *(i2-'1,j2);
                      front_right_cell(f,(len(f|k))-'1,G) = cell(G,i2-'1,
                      j2-'1 ) by A2,A39,A38,A41,A45,A46,A47,A58,GOBRD13:41;
                      then left_cell(f,m,G) misses C by A2,A18,A8,A19,A16,A40
,A46,A47,A48,A50,A59,GOBRD13:25;
                      hence left_cell(f|(k+1),m,G) misses C by A2,A18,A19,A16
,A40,GOBRD13:31;
                      cell(G,i2-'1,j2) meets C by A2,A39,A38,A41,A45,A46,A47
,A44,A58,GOBRD13:28;
                      then right_cell(f,m,G) meets C by A2,A18,A8,A19,A16,A40
,A46,A47,A48,A59,GOBRD13:26;
                      hence right_cell(f|(k+1),m,G) meets C by A2,A18,A19,A16
,A40,GOBRD13:31;
                    end;
                  end;
                  hence thesis;
                end;
                suppose
A60:              front_left_cell(f,(len(f|k))-'1,G) misses C &
                  front_right_cell(f,(len(f|k))-'1,G) meets C;
                  then
A61:              f goes_straight (len(f|k))-'1,G by A1,A18,A8,A39,A43,Def1;
                  now
                    per cases by A38,A45,A46,A47,A61;
                    suppose that
A62:                  i1 = i2 & j1+1 = j2 and
A63:                  [i2,j2+1] in Indices G & f/.(len(f|k)+1) = G*( i2,j2+1);
                      front_left_cell(f,(len(f|k))-'1,G) = cell(G,i1-'1,
                      j2) by A2,A39,A38,A41,A45,A46,A47,A62,GOBRD13:34;
                      then left_cell(f,m,G) misses C by A2,A18,A8,A19,A16,A40
,A46,A47,A60,A62,A63,GOBRD13:21;
                      hence left_cell(f|(k+1),m,G) misses C by A2,A18,A19,A16
,A40,GOBRD13:31;
                      front_right_cell(f,(len(f|k))-'1,G) = cell(G,i1,j2
                      ) by A2,A39,A38,A41,A45,A46,A47,A62,GOBRD13:35;
                      then right_cell(f,m,G) meets C by A2,A18,A8,A19,A16,A40
,A46,A47,A60,A62,A63,GOBRD13:22;
                      hence right_cell(f|(k+1),m,G) meets C by A2,A18,A19,A16
,A40,GOBRD13:31;
                    end;
                    suppose that
A64:                  i1+1 = i2 & j1 = j2 and
A65:                  [i2+1,j2] in Indices G & f/.(len(f|k)+1) = G*( i2+1,j2);
                      front_left_cell(f,(len(f|k))-'1,G) = cell(G,i2,j2)
                      by A2,A39,A38,A41,A45,A46,A47,A64,GOBRD13:36;
                      then left_cell(f,m,G) misses C by A2,A18,A8,A19,A16,A40
,A46,A47,A60,A65,GOBRD13:23;
                      hence left_cell(f|(k+1),m,G) misses C by A2,A18,A19,A16
,A40,GOBRD13:31;
                      front_right_cell(f,(len(f|k))-'1,G) = cell(G,i2,j2
                      -'1) by A2,A39,A38,A41,A45,A46,A47,A64,GOBRD13:37;
                      then right_cell(f,m,G) meets C by A2,A18,A8,A19,A16,A40
,A46,A47,A60,A65,GOBRD13:24;
                      hence right_cell(f|(k+1),m,G) meets C by A2,A18,A19,A16
,A40,GOBRD13:31;
                    end;
                    suppose that
A66:                  i1 = i2+1 & j1 = j2 and
A67:                  [i2-'1,j2] in Indices G & f/.(len(f|k)+1) = G*
                      (i2-'1,j2);
                      front_left_cell(f,(len(f|k))-'1,G) = cell(G,i2-'1,
                      j2-'1) by A2,A39,A38,A41,A45,A46,A47,A66,GOBRD13:38;
                      then left_cell(f,m,G) misses C by A2,A18,A8,A19,A16,A40
,A46,A47,A48,A60,A67,GOBRD13:25;
                      hence left_cell(f|(k+1),m,G) misses C by A2,A18,A19,A16
,A40,GOBRD13:31;
                      front_right_cell(f,(len(f|k))-'1,G) = cell(G,i2-'1
                      ,j2) by A2,A39,A38,A41,A45,A46,A47,A66,GOBRD13:39;
                      then right_cell(f,m,G) meets C by A2,A18,A8,A19,A16,A40
,A46,A47,A48,A60,A67,GOBRD13:26;
                      hence right_cell(f|(k+1),m,G) meets C by A2,A18,A19,A16
,A40,GOBRD13:31;
                    end;
                    suppose that
A68:                  i1 = i2 & j1 = j2+1 and
A69:                  [i2,j2-'1] in Indices G & f/.(len(f|k)+1) = G*
                      (i2,j2-'1);
                      front_left_cell(f,(len(f|k))-'1,G) = cell(G,i2,j2
                      -'1) by A2,A39,A38,A41,A45,A46,A47,A68,GOBRD13:40;
                      then left_cell(f,m,G) misses C by A2,A18,A8,A19,A16,A40
,A46,A47,A49,A60,A69,GOBRD13:27;
                      hence left_cell(f|(k+1),m,G) misses C by A2,A18,A19,A16
,A40,GOBRD13:31;
                      front_right_cell(f,(len(f|k))-'1,G) = cell(G,i2-'1
                      ,j2-'1 ) by A2,A39,A38,A41,A45,A46,A47,A68,GOBRD13:41;
                      then right_cell(f,m,G) meets C by A2,A18,A8,A19,A16,A40
,A46,A47,A49,A60,A69,GOBRD13:28;
                      hence right_cell(f|(k+1),m,G) meets C by A2,A18,A19,A16
,A40,GOBRD13:31;
                    end;
                  end;
                  hence thesis;
                end;
                suppose
A70:              front_left_cell(f,(len(f|k))-'1,G) meets C;
                  then
A71:              f turns_left (len(f|k))-'1,G by A1,A18,A8,A39,A43,Def1;
                  now
                    per cases by A38,A45,A46,A47,A71;
                    suppose that
A72:                  i1 = i2 & j1+1 = j2 and
A73:                  [i2-'1,j2] in Indices G & f/.(len(f|k)+1) = G*
                      (i2-'1,j2);
                      j2-'1 = j1 & cell(G,i1-'1,j1) misses C by A2,A39,A38,A41
,A45,A46,A47,A42,A72,GOBRD13:21,NAT_D:34;
                      then left_cell(f,m,G) misses C by A2,A18,A8,A19,A16,A40
,A46,A47,A48,A72,A73,GOBRD13:25;
                      hence left_cell(f|(k+1),m,G) misses C by A2,A18,A19,A16
,A40,GOBRD13:31;
                      front_left_cell(f,(len(f|k))-'1,G) = cell(G,i1-'1,
                      j2) by A2,A39,A38,A41,A45,A46,A47,A72,GOBRD13:34;
                      then right_cell(f,m,G) meets C by A2,A18,A8,A19,A16,A40
,A46,A47,A48,A70,A72,A73,GOBRD13:26;
                      hence right_cell(f|(k+1),m,G) meets C by A2,A18,A19,A16
,A40,GOBRD13:31;
                    end;
                    suppose that
A74:                  i1+1 = i2 & j1 = j2 and
A75:                  [i2,j2+1] in Indices G & f/.(len(f|k)+1) = G*( i2,j2+1);
                      i2-'1 = i1 & cell(G,i1,j1) misses C by A2,A39,A38,A41,A45
,A46,A47,A42,A74,GOBRD13:23,NAT_D:34;
                      then left_cell(f,m,G) misses C by A2,A18,A8,A19,A16,A40
,A46,A47,A74,A75,GOBRD13:21;
                      hence left_cell(f|(k+1),m,G) misses C by A2,A18,A19,A16
,A40,GOBRD13:31;
                      front_left_cell(f,(len(f|k))-'1,G) = cell(G,i2,j2)
                      by A2,A39,A38,A41,A45,A46,A47,A74,GOBRD13:36;
                      then right_cell(f,m,G) meets C by A2,A18,A8,A19,A16,A40
,A46,A47,A70,A75,GOBRD13:22;
                      hence right_cell(f|(k+1),m,G) meets C by A2,A18,A19,A16
,A40,GOBRD13:31;
                    end;
                    suppose that
A76:                  i1 = i2+1 & j1 = j2 and
A77:                  [i2,j2-'1] in Indices G & f/.(len(f|k)+1) = G*
                      (i2,j2-'1);
                      cell(G,i2,j2-'1) misses C by A2,A39,A38,A41,A45,A46,A47
,A42,A76,GOBRD13:25;
                      then left_cell(f,m,G) misses C by A2,A18,A8,A19,A16,A40
,A46,A47,A49,A77,GOBRD13:27;
                      hence left_cell(f|(k+1),m,G) misses C by A2,A18,A19,A16
,A40,GOBRD13:31;
                      front_left_cell(f,(len(f|k))-'1,G) = cell(G,i2-'1,
                      j2-'1) by A2,A39,A38,A41,A45,A46,A47,A76,GOBRD13:38;
                      then right_cell(f,m,G) meets C by A2,A18,A8,A19,A16,A40
,A46,A47,A49,A70,A77,GOBRD13:28;
                      hence right_cell(f|(k+1),m,G) meets C by A2,A18,A19,A16
,A40,GOBRD13:31;
                    end;
                    suppose that
A78:                  i1 = i2 & j1 = j2+1 and
A79:                  [i2+1,j2] in Indices G & f/.(len(f|k)+1) = G*( i2+1,j2);
                      cell(G,i2,j2) misses C by A2,A39,A38,A41,A45,A46,A47,A42
,A78,GOBRD13:27;
                      then left_cell(f,m,G) misses C by A2,A18,A8,A19,A16,A40
,A46,A47,A79,GOBRD13:23;
                      hence left_cell(f|(k+1),m,G) misses C by A2,A18,A19,A16
,A40,GOBRD13:31;
                      front_left_cell(f,(len(f|k))-'1,G) = cell(G,i2,j2
                      -'1) by A2,A39,A38,A41,A45,A46,A47,A78,GOBRD13:40;
                      then right_cell(f,m,G) meets C by A2,A18,A8,A19,A16,A40
,A46,A47,A70,A79,GOBRD13:24;
                      hence right_cell(f|(k+1),m,G) meets C by A2,A18,A19,A16
,A40,GOBRD13:31;
                    end;
                  end;
                  hence thesis;
                end;
              end;
              hence thesis;
            end;
            suppose
              m+1 <> len(f|(k+1));
              then m+1 < len(f|(k+1)) by A17,XXREAL_0:1;
              then
A80:          m+1 <= len(f|k)by A8,A19,NAT_1:13;
              then consider i1,j1,i2,j2 being Nat such that
A81:          [i1,j1] in Indices G and
A82:          (f|k)/.m = G*(i1,j1) and
A83:          [i2,j2] in Indices G and
A84:          (f|k)/.(m+1) = G*(i2,j2) and
A85:          i1 = i2 & j1+1 = j2 or i1+1 = i2 & j1 = j2 or i1 = i2+
              1 & j1 = j2 or i1 = i2 & j1 = j2+1 by A10,A16,JORDAN8:3;
A86:          left_cell(f|k,m,G) misses C & right_cell(f|k,m,G) meets C
              by A6,A16,A80;
A87:          f|(k+1) = (f|k)^<*f/.(k+1)*> by A18,FINSEQ_5:82;
              1 <= m+1 by NAT_1:12;
              then m+1 in dom(f|k) by A80,FINSEQ_3:25;
              then
A88:          (f|(k+1))/.(m+1) = G*(i2,j2) by A84,A87,FINSEQ_4:68;
              m <= len(f|k) by A80,NAT_1:13;
              then m in dom(f|k) by A16,FINSEQ_3:25;
              then
A89:          (f|(k+1))/.m = G*(i1,j1) by A82,A87,FINSEQ_4:68;
              now
                per cases by A85;
                suppose
A90:              i1 = i2 & j1+1 = j2;
                  then left_cell(f|k,m,G) = cell(G,i1-'1,j1) & right_cell(f|k
,m,G) = cell(G,i1,j1) by A10,A16,A80,A81,A82,A83,A84,GOBRD13:21,22;
                  hence thesis by A11,A16,A17,A81,A83,A86,A89,A88,A90,
GOBRD13:21,22;
                end;
                suppose
A91:              i1+1 = i2 & j1 = j2;
                  then left_cell(f|k,m,G) = cell(G,i1,j1) & right_cell(f|k,m,
G) = cell(G,i1,j1-'1) by A10,A16,A80,A81,A82,A83,A84,GOBRD13:23,24;
                  hence thesis by A11,A16,A17,A81,A83,A86,A89,A88,A91,
GOBRD13:23,24;
                end;
                suppose
A92:              i1 = i2+1 & j1 = j2;
                  then left_cell(f|k,m,G) = cell(G,i2,j2-'1) & right_cell(f|k
,m,G) = cell(G,i2,j2) by A10,A16,A80,A81,A82,A83,A84,GOBRD13:25,26;
                  hence thesis by A11,A16,A17,A81,A83,A86,A89,A88,A92,
GOBRD13:25,26;
                end;
                suppose
A93:              i1 = i2 & j1 = j2+1;
                  then left_cell(f|k,m,G) = cell(G,i2,j2) & right_cell(f|k,m,
G) = cell(G,i1-'1,j2) by A10,A16,A80,A81,A82,A83,A84,GOBRD13:27,28;
                  hence thesis by A11,A16,A17,A81,A83,A86,A89,A88,A93,
GOBRD13:27,28;
                end;
              end;
              hence thesis;
            end;
          end;
          hence thesis;
        end;
      end;
      hence thesis;
    end;
  end;
A94: f|len f = f by FINSEQ_1:58;
A95: P[0] by CARD_1:27;
  for k being Nat holds P[k] from NAT_1:sch 2(A95,A5);
  hence thesis by A94;
end;
