reserve f, g, h for Function;
reserve x, y, z, u, X for set,
  A for non empty set,
  n for Element of NAT,
  f for Function of X, X;
reserve f for c=-monotone Function of bool X, bool X,
  S for Subset of X;
reserve X, Y for non empty set,
  f for Function of X, Y,
  g for Function of Y, X;
reserve L for Lattice,
  f for Function of the carrier of L, the carrier of L,
  x for Element of L,
  O, O1, O2, O3, O4 for Ordinal,
  T for Sequence;
reserve L for complete Lattice,
  f for monotone UnOp of L,
  a, b for Element of L;

theorem Th31:
  for a st f.a [= a ex O st card O c= card the carrier of L & (f,
  O)-.a is_a_fixpoint_of f
proof
  let a;
  set cL = the carrier of L;
  set ccL = card cL;
  set nccL = nextcard ccL;
  deffunc F(Ordinal)=(f, $1)-.a;
  consider Ls being Sequence such that
A1: dom Ls = nccL & for O2 being Ordinal st O2 in nccL holds Ls.O2 = F(
  O2) from ORDINAL2:sch 2;
  assume
A2: f.a [= a;
  now
    assume
A3: for O st O in nccL holds not (f, O)-.a is_a_fixpoint_of f;
A4: Ls is one-to-one
    proof
      let x1,x2 be object;
      assume that
A5:   x1 in dom Ls and
A6:   x2 in dom Ls and
A7:   Ls.x1 = Ls.x2;
      reconsider x1, x2 as Ordinal by A5,A6;
A8:   Ls.x1 = (f, x1)-.a by A1,A5;
A9:   Ls.x2 = (f, x2)-.a by A1,A6;
      per cases by Lm1;
      suppose
A10:    x1 c< x2;
        not (f, x2)-.a is_a_fixpoint_of f by A1,A3,A6;
        hence thesis by A2,A1,A6,A7,A8,A10,Th27;
      end;
      suppose
A11:    x2 c< x1;
        not (f, x1)-.a is_a_fixpoint_of f by A1,A3,A5;
        hence thesis by A2,A1,A5,A7,A9,A11,Th27;
      end;
      suppose
        x2 = x1;
        hence thesis;
      end;
    end;
    rng Ls c= cL
    proof
      let y be object;
      assume y in rng Ls;
      then consider x being object such that
A12:  x in dom Ls and
A13:  Ls.x = y by FUNCT_1:def 3;
      reconsider x as Ordinal by A12;
      Ls.x = (f, x)-.a by A1,A12;
      hence thesis by A13;
    end;
    then card nccL c= ccL by A1,A4,CARD_1:10;
    then
A14: nccL c= ccL;
    ccL in nccL by CARD_1:18;
    hence contradiction by A14,CARD_1:4;
  end;
  then consider O such that
A15: O in nccL and
A16: (f, O)-.a is_a_fixpoint_of f;
  take O;
  card O in nccL by A15,CARD_1:9;
  hence card O c= card cL by CARD_3:91;
  thus thesis by A16;
end;
