reserve r,r1,r2,g,g1,g2,x0,t for Real;
reserve n,k,m for Element of NAT;
reserve seq for Real_Sequence;
reserve f,f1,f2 for PartFunc of REAL,REAL;

theorem Th31:
  f is_convergent_in x0 implies r(#)f is_convergent_in x0 & lim(r
  (#)f,x0)=r*(lim(f,x0))
proof
  assume
A1: f is_convergent_in x0;
A2: now
    let seq;
    assume that
A3: seq is convergent and
A4: lim seq=x0 and
A5: rng seq c=dom(r(#)f)\{x0};
A6: rng seq c=dom f\{x0} by A5,VALUED_1:def 5;
    then
A7: r(#)(f/*seq)=(r(#)f)/*seq by RFUNCT_2:9,XBOOLE_1:1;
A8: f/*seq is convergent by A1,A3,A4,A6;
    then r(#) (f/*seq) is convergent by SEQ_2:7;
    hence (r(#) f)/*seq is convergent by A6,RFUNCT_2:9,XBOOLE_1:1;
    lim(f/*seq)=lim(f,x0) by A1,A3,A4,A6,Def4;
    hence lim((r(#)f)/*seq)=r*(lim(f,x0)) by A8,A7,SEQ_2:8;
  end;
  now
    let r1,r2;
    assume that
A9: r1<x0 and
A10: x0<r2;
    consider g1,g2 such that
A11: r1<g1 and
A12: g1<x0 and
A13: g1 in dom f and
A14: g2<r2 and
A15: x0<g2 and
A16: g2 in dom f by A1,A9,A10;
    take g1;
    take g2;
    thus r1<g1 & g1<x0 & g1 in dom(r(#)f) & g2<r2 & x0<g2 & g2 in dom(r(#)f)
    by A11,A12,A13,A14,A15,A16,VALUED_1:def 5;
  end;
  hence r(#)f is_convergent_in x0 by A2;
  hence thesis by A2,Def4;
end;
