reserve A,B,p,q,r,s for Element of LTLB_WFF,
  n for Element of NAT,
  X for Subset of LTLB_WFF,
  g for Function of LTLB_WFF,BOOLEAN,
  x,y for set;
reserve P,Q,P1,R for PNPair;

theorem Th31: for P be consistent PNPair st not A in rng P holds
  ([(P`1)^^<*A*>,P`2] is consistent or [P`1,(P`2)^^<*A*>] is consistent)
  proof
    let P be consistent PNPair;
    set fpa = P`1^^<*A*>,fma = P`2^^<*A*>,Pl = [fpa,P`2],Pr = [P`1,fma],
    np = 'not' (P^),npl = 'not' (Pl^),npr = 'not' (Pr^),na= <*'not' A*>;
    assume
A1: not A in rng P;
    then not A in rng P`1 by XBOOLE_0:def 3;
    then rng P`1 misses {A} by ZFMISC_1:50;
    then rng P`1 misses rng <*A*> by FINSEQ_1:39;
    then A2: fpa = P`1^<*A*> by Def3;
    not A in rng P`2 by A1,XBOOLE_0:def 3;
    then rng P`2 misses {A} by ZFMISC_1:50;
    then rng P`2 misses rng <*A*> by FINSEQ_1:39;
    then fma = P`2^<*A*> by Def3;
    then A3: nega fma = (nega P`2)^<*'not' A*> by LTLAXIO2:15;
    npl => (npr => np) is ctaut
    proof
      let g;
      set v = VAL g,vf = v.TFALSUM;
A4:   vf = 0 by LTLAXIO1:def 15;
      set p = (v.(P^) '&' v.A) => vf,q = ((v.(P^) '&' (v.A => vf)) => vf);
A5:   v.A = 1 or v.A = 0 by XBOOLEAN:def 3;
A6:   v.(Pr^) = v.kon(P`1) '&' v.kon(nega fma) by LTLAXIO1:31
      .= v.kon(P`1) '&' (v.kon(nega P`2) '&' v.kon(na)) by LTLAXIO2:17,A3
      .= v.kon(P`1) '&' v.kon(nega P`2) '&' v.kon(na)
      .= v.(P^) '&' v.kon(na) by LTLAXIO1:31
      .= v.(P^) '&' v.('not' A) by LTLAXIO2:11
      .= v.(P^) '&' (v.A => vf) by LTLAXIO1:def 15;
A7:   v.(Pl^) = v.kon(fpa) '&' v.kon(nega P`2) by LTLAXIO1:31
      .= v.kon(P`1) '&' v.kon(<*A*>) '&' v.kon(nega P`2) by LTLAXIO2:17,A2
      .= v.kon(P`1) '&' v.A '&' v.kon(nega P`2) by LTLAXIO2:11
      .= v.kon(P`1) '&' v.kon(nega P`2) '&' v.A
      .= v.(P^) '&' v.A by LTLAXIO1:31;
A8:  v.(P^) = 1 or v.(P^) = 0 by XBOOLEAN:def 3;
      thus v.(npl => (npr => np)) = v.npl => v.(npr => np) by LTLAXIO1:def 15
      .= v.npl => (v.npr => v.np) by LTLAXIO1:def 15
      .= p => (v.npr => v.np) by A7,LTLAXIO1:def 15
      .= p => (q => v.np) by A6,LTLAXIO1:def 15
      .= 1 by A8,A5,A4,LTLAXIO1:def 15;
    end;
    then npl => (npr => np) in LTL_axioms by LTLAXIO1:def 17;
    then A9: {} l |- npl => (npr => np) by LTLAXIO1:42;
    assume that
A10: Pl is Inconsistent and
A11: Pr is Inconsistent;
     {} l |- npl by A10;
     then A12: {} l |- (npr => np) by A9,LTLAXIO1:43;
     {} l |- npr by A11;
     hence contradiction by A12,Def10,LTLAXIO1:43;
   end;
