
theorem Th44:
  for A being Cantor-normal-form Ordinal-Sequence
  holds omega -exponent Sum^ A = omega -exponent (A.0)
proof
  defpred P[Nat] means for A being Cantor-normal-form Ordinal-Sequence
    st len A = $1 holds omega -exponent Sum^ A = omega -exponent (A.0);
  A1: P[0]
  proof
    let A be Cantor-normal-form Ordinal-Sequence;
    assume len A = 0;
    then A = {};
    hence omega -exponent Sum^ A = omega -exponent (A.0) by ORDINAL5:52;
  end;
  A3: for n being Nat st P[n] holds P[n+1]
  proof
    let n be Nat;
    assume A4: P[n];
    let A be Cantor-normal-form Ordinal-Sequence;
    assume A5: len A = n+1;
    then A <> {};
    then consider c being Cantor-component Ordinal,
      B being Cantor-normal-form Ordinal-Sequence such that
      A6: A = <% c %> ^ B by ORDINAL5:67;
    per cases;
    suppose A7: B = {};
      Sum^ A = c +^ Sum^ B by A6, ORDINAL5:55
        .= A.0 by A6, A7, ORDINAL5:52, ORDINAL2:27;
      hence thesis;
    end;
    suppose A8: B <> {};
      then {} c< dom B by XBOOLE_1:2, XBOOLE_0:def 8;
      then A9: 0 in dom B by ORDINAL1:11;
      n+1 = len <% c %> + len B by A5, A6, AFINSQ_1:17
        .= len B + 1 by AFINSQ_1:34;
      then A10: omega -exponent Sum^ B = omega -exponent(B.0) by A4;
      A.(len<%c%>+0) = B.0 by A6, A9, AFINSQ_1:def 3;
      then A11: A.1 = B.0 by AFINSQ_1:34;
      len<%c%>+0 in dom A by A6, A9, AFINSQ_1:23;
      then A12: 1 in dom A by AFINSQ_1:34;
      0 in 1 by CARD_1:49, TARSKI:def 1;
      then A13: omega -exponent Sum^ B in omega -exponent(A.0)
        by A10, A11, A12, ORDINAL5:def 11;
      A14: omega -exponent(A.0) c= omega -exponent Sum^ A by Th22, ORDINAL5:56;
      consider d being Ordinal, m being Nat such that
        A15: 0 in Segm m & c = m *^ exp(omega,d) by ORDINAL5:def 9;
      0 in m & m in omega by A15, ORDINAL1:def 12;
      then omega -exponent c = d by A15, ORDINAL5:58;
      then A16: omega -exponent(A.0) = d by A6, AFINSQ_1:35;
      assume omega -exponent Sum^ A <> omega -exponent(A.0);
      then omega -exponent(A.0) in omega -exponent Sum^ A
        by A14, XBOOLE_0:def 8, ORDINAL1:11;
      then A17: exp(omega,d) in exp(omega, omega -exponent Sum^ A)
        by A16, ORDINAL4:24;
      then A18: c in exp(omega, omega -exponent Sum^ A) by A15, Th42;
      set e = omega -exponent Sum^ B;
      A19: 0 in Sum^ B
      proof
        assume not 0 in Sum^ B;
        then Sum^ B c= 0 by ORDINAL1:16;
        hence contradiction by A8;
      end;
      A20: Sum^ B in exp(omega, succ e)
      proof
        assume not Sum^ B in exp(omega, succ e);
        then exp(omega, succ e) c= Sum^ B by ORDINAL1:16;
        then succ e c= e by A19, ORDINAL5:def 10;
        hence contradiction by ORDINAL1:5, ORDINAL1:6;
      end;
      exp(omega,succ e) c= exp(omega,d) by A13, A16, ORDINAL1:21, ORDINAL4:27;
      then Sum^ B in exp(omega,omega-exponent Sum^ A) by A17, A20, ORDINAL1:10;
      then c +^ Sum^ B in exp(omega, omega -exponent Sum^ A) by A18, Th40;
      then A22: Sum^ A in exp(omega, omega-exponent Sum^ A) by A6, ORDINAL5:55;
      Sum^ B c= c +^ Sum^ B by ORDINAL3:24;
      then Sum^ B c= Sum^ A by A6, ORDINAL5:55;
      then exp(omega, omega-exponent Sum^ A) c= Sum^ A by A19, ORDINAL5:def 10;
      then Sum^ A in Sum^ A by A22;
      hence contradiction;
    end;
  end;
  A23: for n being Nat holds P[n] from NAT_1:sch 2(A1,A3);
  let A be Cantor-normal-form Ordinal-Sequence;
  len A is Nat;
  hence thesis by A23;
end;
