reserve K for Ring,
  V1,W1 for VectSp of K;
reserve F for Field,
  V,W for VectSp of F;
reserve T for linear-transformation of V,W;
reserve l for Linear_Combination of V;

theorem Th31:
  for l,m being Linear_Combination of V st (Carrier l) misses (
  Carrier m) holds Carrier (l + m) = (Carrier l) \/ (Carrier m)
proof
  let l,m be Linear_Combination of V such that
A1: (Carrier l) misses (Carrier m);
  thus Carrier (l+m) c= (Carrier l) \/ (Carrier m) by VECTSP_6:23;
  thus (Carrier l) \/ (Carrier m) c= Carrier (l+m)
  proof
    let v be object such that
A2: v in (Carrier l) \/ (Carrier m);
    per cases by A2,XBOOLE_0:def 3;
    suppose
A3:   v in Carrier l;
      then reconsider v as Element of V;
      not v in Carrier m by A1,A2,A3,XBOOLE_0:5;
      then (l+m).v = (l.v) + (m.v) & m.v = 0.F by VECTSP_6:22;
      then
A4:   (l+m).v = l.v by RLVECT_1:4;
      l.v <> 0.F by A3,VECTSP_6:2;
      hence thesis by A4;
    end;
    suppose
A5:   v in Carrier m;
      then reconsider v as Element of V;
      not v in Carrier l by A1,A2,A5,XBOOLE_0:5;
      then (l+m).v = (l.v) + (m.v) & l.v = 0.F by VECTSP_6:22;
      then
A6:   (l+m).v = m.v by RLVECT_1:4;
      m.v <> 0.F by A5,VECTSP_6:2;
      hence thesis by A6;
    end;
  end;
end;
