reserve A for Tolerance_Space,
  X, Y for Subset of A;

theorem
  LAp UAp LAp X = LAp X
proof
  UAp LAp X c= X
  proof
    let y be object;
    assume y in UAp LAp X;
    then Class (the InternalRel of A, y) meets LAp X by Th10;
    then consider z being object such that
A1: z in Class (the InternalRel of A, y) and
A2: z in LAp X by XBOOLE_0:3;
    [z,y] in the InternalRel of A by A1,EQREL_1:19;
    then [y,z] in the InternalRel of A by EQREL_1:6;
    then
A3: y in Class (the InternalRel of A, z) by EQREL_1:19;
    Class (the InternalRel of A, z) c= X by A2,Th8;
    hence thesis by A3;
  end;
  hence LAp UAp LAp X c= LAp X by Th24;
  thus LAp X c= LAp UAp LAp X
  proof
    let x be object;
    assume
A4: x in LAp X;
    Class (the InternalRel of A, x) c= UAp LAp X
    proof
      let y be object;
      assume
A5:   y in Class (the InternalRel of A, x);
      then [y,x] in the InternalRel of A by EQREL_1:19;
      then [x,y] in the InternalRel of A by EQREL_1:6;
      then x in Class (the InternalRel of A, y) by EQREL_1:19;
      then Class (the InternalRel of A, y) meets LAp X by A4,XBOOLE_0:3;
      hence thesis by A5;
    end;
    hence thesis by A4;
  end;
end;
