reserve p,p1,p2,p3,p11,p22,q,q1,q2 for Point of TOP-REAL 2,
  f,h for FinSequence of TOP-REAL 2,
  r,r1,r2,s,s1,s2 for Real,
  u,u1,u2,u5 for Point of Euclid 2,
  n,m,i,j,k for Nat,
  N for Nat,
  x,y,z for set;
reserve lambda for Real;

theorem Th31:
  p`1 = q`1 & p`2 <> q`2 implies LSeg(p,|[p`1,(p`2+q`2)/2]|) /\
  LSeg(|[p`1,(p`2+q`2)/2]|,q)={|[p`1,(p`2+q`2)/2]|}
proof
  assume that
A1: p`1 = q`1 and
A2: p`2 <> q`2;
  set p3 = |[p`1,(p`2+q`2)/2]|;
  set l23 = LSeg(p,p3), l = LSeg(p3,q);
  thus l23 /\ l c= {p3}
  proof
    let x be object;
A3: l23 = LSeg(|[p`1,p`2]|,|[p`1,(p`2+q`2)/2]|) by EUCLID:53;
    assume
A4: x in l23 /\ l;
    then
A5: x in l by XBOOLE_0:def 4;
A6: l = LSeg(|[q`1,(p`2+q`2)/2]|,|[q`1,q`2]|) by A1,EUCLID:53;
A7: x in l23 by A4,XBOOLE_0:def 4;
    now
      per cases by A2,XXREAL_0:1;
      suppose
A8:     p`2 < q`2;
        then p`2 < (p`2+q`2)/2 by XREAL_1:226;
        then x in {p1: p1 `1 = p`1 & p`2 <= p1 `2 & p1 `2 <= (p`2+q`2)/2} by A7
,A3,Th9;
        then consider t1 be Point of TOP-REAL 2 such that
A9:     t1 = x and
A10:    t1 `1 = p`1 and
        p`2 <= t1 `2 and
A11:    t1 `2 <= (p`2+q`2)/2;
A12:    t1`2 <= p3 `2 by A11;
        (p`2+q`2)/2 < q`2 by A8,XREAL_1:226;
        then x in {p2: p2 `1 = q`1 & (p`2+q`2)/2 <= p2 `2 & p2 `2 <= q`2} by A5
,A6,Th9;
        then
        ex t2 be Point of TOP-REAL 2 st t2 = x & t2 `1 = q`1 & (p`2+q`2)/
        2 <= t2 `2 & t2 `2 <= q`2;
        then t1`2 >= p3 `2 by A9;
        then
A13:    t1`2 = p3 `2 by A12,XXREAL_0:1;
        t1 `1 = p3 `1 by A10;
        hence x=p3 by A9,A13,Th6;
      end;
      suppose
A14:    p`2 > q`2;
        then p`2 > (p`2+q`2)/2 by XREAL_1:226;
        then x in {p11: p11 `1 = p`1 & (p`2+q`2)/2<=p11 `2 & p11 `2<= p`2} by
A7,A3,Th9;
        then consider t1 be Point of TOP-REAL 2 such that
A15:    t1 = x and
A16:    t1 `1 = p`1 and
A17:    (p`2+q`2)/2 <= t1 `2 and
        t1 `2 <= p`2;
A18:    p3 `2 <= t1 `2 by A17;
        q`2 < (p`2+q`2)/2 by A14,XREAL_1:226;
        then
        x in {p22: p22 `1=q`1 & q`2<=p22 `2 & p22 `2<=(p`2+q`2)/2} by A5,A6,Th9
;
        then ex t2 be Point of TOP-REAL 2 st t2 = x & t2 `1 = q`1 & q`2 <= t2
        `2 & t2 `2 <= (p`2+q`2)/2;
        then t1`2 <= p3 `2 by A15;
        then
A19:    t1`2 = p3 `2 by A18,XXREAL_0:1;
        t1 `1 = p3 `1 by A16;
        hence x=p3 by A15,A19,Th6;
      end;
    end;
    hence thesis by TARSKI:def 1;
  end;
  let x be object;
  assume x in {p3};
  then
A20: x=p3 by TARSKI:def 1;
  p3 in l23 & p3 in l by RLTOPSP1:68;
  hence thesis by A20,XBOOLE_0:def 4;
end;
