
theorem :: 1.7. COROLLARY, (1) <=> (2), p. 181
  for L being complete LATTICE, k being kernel Function of L,L holds
  k is directed-sups-preserving iff
  for X being Scott TopAugmentation of Image k
  for Y being Scott TopAugmentation of L
  for V being Subset of L st V is open Subset of X
  holds uparrow V is open Subset of Y
proof
  let L be complete LATTICE, k be kernel Function of L,L;
A1: [corestr k, inclusion k] is Galois by WAYBEL_1:39;
  then
A2: corestr k is upper_adjoint;
  then
A3: inclusion k = LowerAdj corestr k by A1,Def1;
  hereby
    assume
A4: k is directed-sups-preserving;
    let X be Scott TopAugmentation of Image k;
    let Y be Scott TopAugmentation of L;
A5: the RelStr of X = Image k by YELLOW_9:def 4;
    let V be Subset of L;
    assume V is open Subset of X;
    then reconsider A = V as open Subset of X;
    reconsider B = A as Subset of Image k by A5;
A6: corestr k is directed-sups-preserving by A4,Th30;
    (inclusion k).:B = V by WAYBEL15:12;
    hence uparrow V is open Subset of Y by A2,A3,A6,Th21;
  end;
  assume
A7: for X being Scott TopAugmentation of Image k
  for Y being Scott TopAugmentation of L
  for V being Subset of L st V is open Subset of X
  holds uparrow V is open Subset of Y;
  now
    set g = corestr k;
    let X be Scott TopAugmentation of Image k;
    let Y be Scott TopAugmentation of L;
    let V be open Subset of X;
    the RelStr of X = Image k by YELLOW_9:def 4;
    then reconsider B = V as Subset of Image k;
    the carrier of Image k c= the carrier of L by YELLOW_0:def 13;
    then reconsider A = B as Subset of L by XBOOLE_1:1;
    uparrow A is open Subset of Y by A7;
    hence uparrow ((LowerAdj g).:V) is open Subset of Y by A3,WAYBEL15:12;
  end;
  then corestr k is directed-sups-preserving by A2,Th21;
  hence thesis by Th30;
end;
