reserve
  S for (4,1) integer bool-correct non empty non void BoolSignature,
  X for non-empty ManySortedSet of the carrier of S,
  T for vf-free integer all_vars_including inheriting_operations free_in_itself
  (X,S)-terms VarMSAlgebra over S,
  C for (4,1) integer bool-correct non-empty image of T,
  G for basic GeneratorSystem over S,X,T,
  A for IfWhileAlgebra of the generators of G,
  I for integer SortSymbol of S,
  x,y,z,m for pure (Element of (the generators of G).I),
  b for pure (Element of (the generators of G).the bool-sort of S),
  t,t1,t2 for Element of T,I,
  P for Algorithm of A,
  s,s1,s2 for Element of C-States(the generators of G);
reserve
  f for ExecutionFunction of A, C-States(the generators of G),
  (\falseC)-States(the generators of G, b);
reserve u for ManySortedFunction of FreeGen T, the Sorts of C;

theorem
  for a being boolean object
  for t being Element of T, the bool-sort of S holds
  \nott value_at(C,s) = 'not' a iff t value_at(C,s) = a
  proof
    let a be boolean object;
    let t be Element of T, the bool-sort of S;
    hereby
      assume \nott value_at(C,s) = 'not' a;
      then \not(t value_at(C,s)) = 'not' a by Th31;
      then 'not' (t value_at(C,s)) = 'not' a by AOFA_A00:def 32;
      hence t value_at(C,s) = a;
    end;
    assume A1: t value_at(C,s) = a;
    \not(t value_at(C,s)) = \nott value_at(C,s) by Th31;
    hence \nott value_at(C,s) = 'not' a by A1,AOFA_A00:def 32;
  end;
