 reserve n for Nat;
 reserve s1 for sequence of Euclid n,
         s2 for sequence of REAL-NS n;

theorem Th29:
  for a,b being Real_Sequence, S being SetSequence of Euclid 1 st
  a.0 = b.0 & S = IntervalSequence(a,b) & (for i being Nat holds
  ((a.(i+1) = a.i & b.(i+1) = (a.i+b.i)/2 ) or
  (a.(i+1) = (a.i + b.i)/2 & b.(i+1) = b.i)))
  holds for i being Nat holds a.i = a.0 & b.i = b.0 & (diameter S).i = 0
  proof
    let a,b be Real_Sequence, S be SetSequence of Euclid 1;
    assume that
A1: a.0 = b.0 and
A2: S = IntervalSequence(a,b) and
A3: for i being Nat holds
    (a.(i+1) = a.i & b.(i+1) = (a.i+b.i)/2 ) or
    (a.(i+1) = (a.i + b.i)/2 & b.(i+1) = b.i);
    defpred P[Nat] means a.$1 = a.0 & b.$1 = b.0;
A4: P[0];
A5: for k be Nat st P[k] holds P[k+1]
    proof
      let k be Nat;
      assume
A6:   P[k];
      (a.(k+1) = a.k & b.(k+1) = (a.k+b.k)/2) or
      (a.(k+1)=(a.k+b.k)/2 & b.(k+1) = b.k) by A3;
      hence thesis by A1,A6;
    end;
A7: for k be Nat holds P[k] from NAT_1:sch 2(A4,A5);
    let i be Nat;
    thus
A8: a.i = a.0 by A7;
    thus
A9: b.i = b.0 by A7;
    (diameter S).i= b.i - a.i by A1,A2,A3,Th28;
    hence (diameter S).i = 0 by A1,A8,A9;
  end;
