reserve n,m,k for Element of NAT;
reserve x, X,X1,Z,Z1 for set;
reserve s,g,r,p,x0,x1,x2 for Real;
reserve s1,s2,q1 for Real_Sequence;
reserve Y for Subset of REAL;
reserve f,f1,f2 for PartFunc of REAL,REAL;

theorem Th32:
  f|X is Lipschitzian iff ex r st 0<r & for x1,x2 st x1 in dom(f|X
  ) & x2 in dom(f|X) holds |.f.x1-f.x2.|<=r*|.x1-x2.|
proof
  thus f|X is Lipschitzian implies ex r st 0<r & for x1,x2 st x1 in dom(f|X) &
  x2 in dom(f|X) holds |.f.x1-f.x2.|<=r*|.x1-x2.|
  proof
    given r such that
A1: 0<r and
A2: for x1,x2 st x1 in dom(f|X) & x2 in dom(f|X) holds |.(f|X).x1-(f
    |X).x2.|<=r*|.x1-x2.|;
    take r;
    thus 0<r by A1;
    let x1,x2;
    assume
A3: x1 in dom(f|X) & x2 in dom(f|X);
    then (f|X).x1 = f.x1 & (f|X).x2 = f.x2 by FUNCT_1:47;
    hence thesis by A2,A3;
  end;
  given r such that
A4: 0<r and
A5: for x1,x2 st x1 in dom(f|X) & x2 in dom(f|X) holds |.f.x1-f.x2.|<=r
  *|.x1-x2.|;
  take r;
  thus 0<r by A4;
  let x1,x2;
  assume
A6: x1 in dom(f|X) & x2 in dom(f|X);
  then (f|X).x1 = f.x1 & (f|X).x2 = f.x2 by FUNCT_1:47;
  hence thesis by A5,A6;
end;
