
theorem helpa:
for R being Ring
for S being RingExtension of R
for T being Subset of S holds RAdj(R,T) == R iff T is Subset of R
proof
let R be Ring, S be RingExtension of R; let T be Subset of S;
set P = RAdj(R,T);
X0: R is Subring of S by FIELD_4:def 1;
X1: R is Subring of R by LIOUVIL2:18;
Z: now let o be object;
   assume C1: o in the carrier of R;
   the carrier of R c= the carrier of S by X0,C0SP1:def 3;
   then reconsider a = o as Element of S by C1;
   now let U be Subring of S;
     assume R is Subring of U & T is Subset of U;
     then the carrier of R c= the carrier of U by C0SP1:def 3;
     hence o in U by C1;
     end;
   then a in carrierRA(T);
   hence o in the carrier of P by FIELD_6:def 4;
   end;
G:now assume B0: T is Subset of R;
  now let o be object;
      assume o in the carrier of P;
      then o in carrierRA(T) by FIELD_6:def 4;
      then consider x being Element of S such that
      B1: x = o & for U being Subring of S
                  st R is Subring of U & T is Subset of U holds x in U;
      x in R by X0,X1,B0,B1;
      hence o in the carrier of R by B1;
      end; then
  B1: the carrier of R = the carrier of P by Z,TARSKI:2;
  B2: 1.P = 1.S by FIELD_6:def 4 .= 1.R by X0,C0SP1:def 3;
  B3: 0.P = 0.S by FIELD_6:def 4 .= 0.R by X0,C0SP1:def 3;
  B4: the addF of P = (the addF of S)||carrierRA(T) by FIELD_6:def 4
                   .= (the addF of S)||the carrier of R by B1,FIELD_6:def 4
                   .= (the addF of R)||the carrier of R by X0,C0SP1:def 3;
  the multF of P = (the multF of S)||carrierRA(T) by FIELD_6:def 4
                .= (the multF of S)||the carrier of R by B1,FIELD_6:def 4
                .= (the multF of R)||the carrier of R by X0,C0SP1:def 3;
  hence RAdj(R,T) == R by B1,B2,B3,B4,FIELD_7:def 1;
  end;
now assume RAdj(R,T) == R; then
  the doubleLoopStr of RAdj(R,T) = the doubleLoopStr of R by FIELD_7:def 1;
  hence T is Subset of R by FIELD_6:30;
  end;
hence thesis by G;
end;
