reserve i,j,k for Nat,
  r,s,r1,r2,s1,s2,sb,tb for Real,
  x for set,
  GX for non empty TopSpace;
reserve GZ for non empty TopSpace;
reserve f for non constant standard special_circular_sequence,
  G for non empty-yielding Matrix of TOP-REAL 2;
reserve G for non empty-yielding X_equal-in-line Y_equal-in-column Matrix of
  TOP-REAL 2;

theorem Th32:
  1 <= i & i < len G & 1 <= j & j < width G implies cell(G,i,j) =
{ |[r,s]| : G*(i,1)`1 <= r & r <= G*(i+1,1)`1 & G*(1,j)`2 <= s & s <= G*(1,j+1)
  `2 }
proof
  assume that
A1: 1 <= i & i < len G and
A2: 1 <= j & j < width G;
A3: h_strip(G,j) = { |[r,s]| : G*(1,j)`2 <= s & s <= G* (1,j+1)`2 } by A2,Th23;
A4: cell(G,i,j) = v_strip(G,i) /\ h_strip(G,j) by GOBOARD5:def 3;
A5: v_strip(G,i) = { |[r,s]| : G*(i,1)`1 <= r & r <= G* (i+1,1)`1 } by A1,Th20;
  thus cell(G,i,j) c= { |[r,s]| : G*(i,1)`1 <= r & r <= G*(i+1,1)`1 & G*(1,j)
  `2 <= s & s <= G*(1,j+1)`2 }
  proof
    let x be object;
    assume
A6: x in cell(G,i,j);
    then x in v_strip(G,i) by A4,XBOOLE_0:def 4;
    then consider r1,s1 such that
A7: x = |[r1,s1]| and
A8: G*(i,1)`1 <= r1 & r1 <= G*(i+1,1)`1 by A5;
    x in h_strip(G,j) by A4,A6,XBOOLE_0:def 4;
    then consider r2,s2 such that
A9: x = |[r2,s2]| and
A10: G*(1,j)`2 <= s2 & s2 <= G*(1,j+1)`2 by A3;
    s1 = s2 by A7,A9,SPPOL_2:1;
    hence thesis by A7,A8,A10;
  end;
  let x be object;
  assume x in { |[r,s]| : G*(i,1)`1 <= r & r <= G*(i+1,1)`1 & G*(1,j)`2 <= s
  & s <= G*(1,j+1)`2 };
  then
A11: ex r,s st x = |[r,s]| & G*(i,1)`1 <= r & r <= G*(i+1,1)`1 & G*(1,j)`2
  <= s & s <= G*(1,j+1)`2;
  then
A12: x in h_strip(G,j) by A3;
  x in v_strip(G,i) by A5,A11;
  hence thesis by A4,A12,XBOOLE_0:def 4;
end;
