reserve X for set;
reserve G for Group;
reserve H for Subgroup of G;
reserve h,x,y for object;
reserve f for Endomorphism of G;
reserve phi for Automorphism of G;

theorem Th33:
  for H being strict Subgroup of G
  holds H is normal iff for f being inner Automorphism of G holds Image(f|H)=H
proof
  let H be strict Subgroup of G;
  thus H is normal implies
   for f being inner Automorphism of G holds Image(f|H)=H
  proof
    assume B1: H is normal;
    let f be inner Automorphism of G;
    consider a being Element of G such that
    B2: a is_inner_wrt f by Def2;
    Image(f|H) = H |^ a by B2,Th28
              .= the multMagma of H by B1,GROUP_3:def 13
              .= H;
    hence Image(f|H)=H;
  end;
  assume B1: for f being inner Automorphism of G holds Image(f|H)=H;
  assume not H is normal;
  then consider a being Element of G such that
B2: H |^ a <> the multMagma of H
    by GROUP_3:def 13;
    consider f being inner Automorphism of G such that
B3: a is_inner_wrt f by Th32;
    Image(f|H) = H |^ a by B3,Th28;
    hence contradiction by B1,B2;
end;
