reserve x for Real;
reserve p,q for Point of TOP-REAL 2;

theorem Th32:
  for X being non empty TopSpace, f1,f2 being Function of X,R^1 st
f1 is continuous & f2 is continuous & (for q being Point of X holds f2.q<>0) ex
g being Function of X,R^1 st (for p being Point of X,r1,r2 being Real st
  f1.p=r1 & f2.p=r2 holds g.p=r2*sqrt(1+(r1/r2)^2)) & g is continuous
proof
  let X be non empty TopSpace, f1,f2 be Function of X,R^1;
  assume that
A1: f1 is continuous and
A2: f2 is continuous and
A3: for q being Point of X holds f2.q<>0;
  consider g2 being Function of X,R^1 such that
A4: for p being Point of X,r1,r2 being Real st f1.p=r1 & f2.p=r2
  holds g2.p=sqrt(1+(r1/r2)^2) and
A5: g2 is continuous by A1,A2,A3,Th8;
  consider g3 being Function of X,R^1 such that
A6: for p being Point of X,r2,r0 being Real st f2.p=r2 & g2.p=r0
  holds g3.p=r2*r0 and
A7: g3 is continuous by A2,A5,JGRAPH_2:25;
  for p being Point of X,r1,r2 being Real st f1.p=r1 & f2.p=r2
  holds g3.p=r2*sqrt(1+(r1/r2)^2)
  proof
    let p be Point of X,r1,r2 be Real;
    assume that
A8: f1.p=r1 and
A9: f2.p=r2;
    g2.p=sqrt(1+(r1/r2)^2) by A4,A8,A9;
    hence thesis by A6,A9;
  end;
  hence thesis by A7;
end;
