reserve p,p1,p2,p3,q,q1,q2 for Point of TOP-REAL 2,
  i for Nat,
  lambda for Real;

theorem Th32:
  for a,b,c,d being Real st a <= b & c <= d holds
  LSeg(|[a,c]|,|[b,c]|) /\ LSeg(|[b,c]|,|[b,d]|) = {|[b,c]|}
proof
  let a,b,c,d be Real;
  assume that
A1: a <= b and
A2: c <= d;
  for ax being object
  holds ax in LSeg(|[a,c]|,|[b,c]|) /\ LSeg(|[b,c]|,|[b,d]|) iff ax = |[b,c]|
  proof
    let ax be object;
    thus ax in LSeg(|[a,c]|,|[b,c]|) /\ LSeg(|[b,c]|,|[b,d]|)
    implies ax = |[b,c]|
    proof
      assume
A3:   ax in LSeg(|[a,c]|,|[b,c]|) /\ LSeg(|[b,c]|,|[b,d]|);
      then
A4:   ax in LSeg(|[a,c]|,|[b,c]|) by XBOOLE_0:def 4;
A5:   ax in LSeg(|[b,c]|,|[b,d]|) by A3,XBOOLE_0:def 4;
      ax in { q1 : q1`1 <= b & q1`1 >= a & q1`2 = c} by A1,A4,Th30;
      then
A6:   ex p2 st p2 = ax & p2`1 <= b & p2`1 >= a & p2`2 = c;
      ax in { q2 : q2`1 = b & q2`2 <= d & q2`2 >= c} by A2,A5,Th30;
      then ex p st p = ax & p`1 = b & p`2 <= d & p`2 >= c;
      hence thesis by A6,EUCLID:53;
    end;
    assume
A7: ax = |[b,c]|;
    then
A8: ax in LSeg(|[a,c]|,|[b,c]|) by RLTOPSP1:68;
    ax in LSeg(|[b,c]|,|[b,d]|) by A7,RLTOPSP1:68;
    hence thesis by A8,XBOOLE_0:def 4;
  end;
  hence thesis by TARSKI:def 1;
end;
